netdata/trunk/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
   2 # Contributor: SanskritFritz (gmail)
   3
   4 pkgname=netdata
   5 pkgver=1.39.0
   6 pkgrel=1
   7 pkgdesc="Real-time performance monitoring, in the greatest possible detail, over the web"
   8 url="https://github.com/netdata/netdata"
   9 arch=('x86_64')
  10 license=('GPL')
  11 backup=('etc/netdata/netdata.conf')
  12 depends=('libmnl' 'libnetfilter_acct' 'zlib' 'judy' 'libuv' 'json-c' 'libcap' 'lz4' 'openssl' 'which' 'snappy' 'protobuf'
  13          'libwebsockets' 'mongo-c-driver' 'libyaml')
  14 makedepends=('cups')
  15 optdepends=('nodejs: for monitoring named and SNMP devices'
  16             'lm_sensors: for monitoring hardware sensors'
  17             'iproute2: for monitoring Linux QoS'
  18             'python: for most of the external plugins'
  19             'python-psycopg2: for monitoring PostgreSQL databases'
  20             'python-mysqlclient: for monitoring MySQL/MariaDB databases'
  21             'python-requests: for monitoring elasticsearch'
  22             'hddtemp: for monitoring hhd temperature'
  23             'fping: for for fping module'
  24             'apcupsd: for monitoring APC UPS'
  25             'cups: for CUPS plugin'
  26             'iw: for monitoring Linux as access point')
  27 install=$pkgname.install
  28 source=("$pkgname-$pkgver.tar.gz::https://github.com/netdata/netdata/releases/download/v$pkgver/netdata-v$pkgver.tar.gz"
  29         "$pkgname.sysusers")
  30 sha512sums=('edb668d86b707c584094ad3f6e50fa646d847883fb326e38431d5036f9dfa4857514476f7e50a863ef8533035289c9725ca5ae5da08fbee32bda1a2e3ac48a36'
  31             'a910809a823ba58ca7bdaa72e8d68427b48f452c1fbb2343fa182ecb0a091a7640e73af24b8ba2fdd90e00aed8ef53b7fccd25cb8f04ca9b9fa6c8e52223ca66')
  32
  33 build() {
  34   cd "$pkgname-v$pkgver"
  35
  36   autoreconf -i
  37   ./configure \
  38       --prefix="/usr" \
  39       --sbindir="/usr/bin" \
  40       --sysconfdir="/etc" \
  41       --libexecdir="/usr/lib" \
  42       --localstatedir="/var" \
  43       --with-zlib --with-math --with-user=netdata
  44   make
  45 }
  46
  47 package() {
  48   cd "$pkgname-v$pkgver"
  49
  50   make DESTDIR="$pkgdir" install
  51
  52   install -Dm644 system/netdata.conf "$pkgdir"/etc/netdata/netdata.conf
  53   chown -R 0:134 "$pkgdir"/usr/share/netdata/web
  54
  55   install -Dm0644 "system/systemd/netdata.service.v235" "$pkgdir/usr/lib/systemd/system/netdata.service"
  56   install -Dm0644 "system/logrotate/netdata" "$pkgdir/etc/logrotate.d/netdata"
  57   install -Dm0644 "${srcdir}/${pkgname}.sysusers" "${pkgdir}/usr/lib/sysusers.d/${pkgname}.conf"
  58 }