networkmanager-fortisslvpn/trunk/PKGBUILD

   1 # Maintainer: Bartłomiej Piotrowski <bpiotrowski@archlinux.org>
   2
   3 pkgname=networkmanager-fortisslvpn
   4 pkgver=1.4.0
   5 pkgrel=2
   6 pkgdesc="NetworkManager VPN plugin for Fortinet SSLVPN"
   7 url="https://wiki.gnome.org/Projects/NetworkManager"
   8 arch=(x86_64)
   9 license=(GPL)
  10 _pppver=2.4.9
  11 depends=(libnm libsecret "ppp=$_pppver" openfortivpn)
  12 makedepends=(libnma libnma-gtk4 intltool python git)
  13 optdepends=('libnma: GUI support (GTK 3)'
  14             'libnma-gtk4: GUI support (GTK 4)')
  15 _commit=308987d45faee919e54547eb7ff0120c32c5a84e  # tags/1.4.0^0
  16 source=("git+https://gitlab.gnome.org/GNOME/NetworkManager-fortisslvpn.git#commit=$_commit")
  17 sha256sums=('SKIP')
  18
  19 pkgver() {
  20   cd NetworkManager-fortisslvpn
  21   git describe --tags | sed 's/-dev/dev/;s/[^-]*-g/r&/;s/-/+/g'
  22 }
  23
  24 prepare() {
  25   cd NetworkManager-fortisslvpn
  26   intltoolize --automake --copy
  27   autoreconf -fvi
  28 }
  29
  30 build() {
  31   cd NetworkManager-fortisslvpn
  32   ./configure --prefix=/usr --sysconfdir=/etc --localstatedir=/var \
  33     --libexecdir=/usr/lib --disable-static --with-gtk4 \
  34     --with-pppd-plugin-dir=/usr/lib/pppd/$_pppver
  35   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  36   make
  37 }
  38
  39 package() {
  40   cd NetworkManager-fortisslvpn
  41   make DESTDIR="$pkgdir" install dbusservicedir=/usr/share/dbus-1/system.d
  42 }
  43
  44 # vim:set sw=2 et: