oath-toolkit/trunk/PKGBUILD

   1 # Maintainer: Christian Hesse <mail@eworm.de>
   2 # Contributor: Sébastien Luttringer
   3 # Contributor: L42y <423300@gmail.com>
   4
   5 pkgname=oath-toolkit
   6 pkgver=2.6.7
   7 pkgrel=1
   8 pkgdesc='OATH one-time password toolkit'
   9 arch=('x86_64')
  10 url='https://www.nongnu.org/oath-toolkit/'
  11 license=('GPL3')
  12 depends=('glibc' 'pam' 'xmlsec')
  13 provides=('liboath.so' 'libpskc.so')
  14 validpgpkeys=('B1D2BD1375BECB784CF4F8C4D73CF638C53C06BE') # Simon Josefsson <simon@josefsson.org>
  15 source=("https://download.savannah.nongnu.org/releases/$pkgname/$pkgname-$pkgver.tar.gz"{,.sig})
  16 sha256sums=('36eddfce8f2f36347fb257dbf878ba0303a2eaafe24eaa071d5cd302261046a9'
  17             'SKIP')
  18
  19 build() {
  20   cd $pkgname-$pkgver
  21
  22   ./configure --prefix=/usr
  23   make
  24 }
  25
  26 check() {
  27   cd $pkgname-$pkgver
  28
  29   make check
  30 }
  31
  32 package() {
  33   cd $pkgname-$pkgver
  34
  35   make DESTDIR="$pkgdir" install
  36
  37   # Install basic docs too
  38   install -D -m 0644 pam_oath/README "$pkgdir/usr/share/doc/$pkgname/PAM_README"
  39   install -D -m 0644 README "$pkgdir/usr/share/doc/$pkgname/README"
  40 }