ocaml-ppx_derivers/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Daniel Peukert <dan.peukert@gmail.com>
   3 # Contributor: Jakob Gahde <j5lx@fmail.co.uk>
   4
   5 _projectname='ppx_derivers'
   6 pkgname="ocaml-$_projectname"
   7 pkgver=1.2.1
   8 pkgrel=10
   9 pkgdesc='Shared deriving plugin registry'
  10 arch=('x86_64')
  11 url="https://github.com/ocaml-ppx/$_projectname"
  12 license=('BSD')
  13 depends=('ocaml')
  14 makedepends=('dune')
  15 options=('!strip')
  16 source=("$pkgname-$pkgver-$pkgrel.tar.gz::$url/archive/$pkgver.tar.gz")
  17 sha256sums=('b6595ee187dea792b31fc54a0e1524ab1e48bc6068d3066c45215a138cc73b95')
  18
  19 _sourcedirectory="$_projectname-$pkgver"
  20
  21 build() {
  22         cd "$srcdir/$_sourcedirectory/"
  23         dune build -p "$_projectname" --verbose
  24 }
  25
  26 package() {
  27         cd "$srcdir/$_sourcedirectory/"
  28         DESTDIR="$pkgdir" dune install --prefix '/usr' --libdir "/usr/lib/ocaml"
  29
  30         install -dm755 "$pkgdir/usr/share/doc/$pkgname"
  31         mv "$pkgdir/usr/doc/$_projectname/"* "$pkgdir/usr/share/doc/$pkgname/"
  32         rm -r "$pkgdir/usr/doc/"
  33
  34         install -dm755 "$pkgdir/usr/share/licenses/$pkgname"
  35         ln -sf "/usr/share/doc/$pkgname/LICENSE.md" "$pkgdir/usr/share/licenses/$pkgname/LICENSE.md"
  36 }