openra/repos/community-any/PKGBUILD

   1 # Maintainer: Sven-Hendrik Haase <svenstaro@archlinux.org>
   2 # Contributor: Matthew Bowra-Dean <matthew@ijw.co.nz>
   3 pkgname=openra
   4 pkgver=20230225
   5 pkgrel=1
   6 pkgdesc="An open-source implementation of the Red Alert engine using .NET/Mono and OpenGL"
   7 arch=('any')
   8 url="https://www.openra.net"
   9 license=('GPL3')
  10 install=openra.install
  11 depends=('ttf-dejavu' 'openal' 'libgl' 'freetype2' 'sdl2' 'lua51' 'hicolor-icon-theme'
  12          'gtk-update-icon-cache' 'desktop-file-utils' 'xdg-utils' 'zenity' 'dotnet-sdk-6.0')
  13 makedepends=('git' 'unzip')
  14 options=(!debug)
  15 source=("git+https://github.com/OpenRA/OpenRA.git#tag=release-${pkgver}")
  16 sha512sums=('SKIP')
  17
  18 prepare() {
  19   cd OpenRA
  20
  21   make version VERSION="release-${pkgver}"
  22 }
  23
  24 build() {
  25   cd OpenRA
  26
  27   make RUNTIME=net6 TARGETPLATFORM=unix-generic
  28 }
  29
  30 package() {
  31   cd OpenRA
  32   mkdir -p "$pkgdir/usr/lib/openra/"
  33   cp -r bin/* "$pkgdir/usr/lib/openra/"
  34   source ./packaging/functions.sh
  35   install_data . "$pkgdir/usr/lib/openra/" cnc d2k ra
  36   make prefix=/usr DESTDIR="$pkgdir" install-linux-shortcuts
  37   make prefix=/usr DESTDIR="$pkgdir" install-linux-appdata
  38   # make prefix=/usr DESTDIR="$pkgdir" install-man
  39 }