perl-gtk3-imageview/trunk/PKGBUILD

   1 # Maintainer: Muflone http://www.muflone.com/contacts/english/
   2
   3 pkgname=perl-gtk3-imageview
   4 _perl_namespace=Gtk3
   5 _perl_module=ImageView
   6 pkgver=10
   7 pkgrel=3
   8 pkgdesc="Image viewer widget for Gtk3"
   9 arch=('any')
  10 url="https://metacpan.org/release/${_perl_namespace}-${_perl_module}"
  11 license=('LGPL')
  12 depends=('perl-gtk3' 'imagemagick')
  13 checkdepends=('perl-test-exception' 'perl-test-memory-cycle' 'perl-try-tiny'
  14               'perl-readonly' 'perl-test-mockobject' 'perl-test-differences'
  15               'perl-test-deep' 'perl-carp-always' 'xorg-server-xvfb')
  16 source=("https://cpan.metacpan.org/authors/id/A/AS/ASOKOLOV/${_perl_namespace}-${_perl_module}-${pkgver}.tar.gz")
  17 sha512sums=('2548c33c49c27bb4a69d5512c7dfaca096a39ef6d08fa1deb83a045e6c5b7ad075eb8b23b33fb794024c9b9e7fd979a5c31bff075a7ed5412a4a5a4f53824f5a')
  18 options=('!emptydirs')
  19
  20 build() {
  21   cd "${_perl_namespace}-${_perl_module}-${pkgver}"
  22   unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  23   export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
  24   perl Makefile.PL
  25   make
  26 }
  27
  28 check() {
  29   cd "${_perl_namespace}-${_perl_module}-${pkgver}"
  30   unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  31   export PERL_MM_USE_DEFAULT=1
  32   xvfb-run -a -s "-extension GLX -screen 0 1280x1024x24" make test
  33 }
  34
  35 package() {
  36   cd "${_perl_namespace}-${_perl_module}-${pkgver}"
  37   unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  38   make pure_install INSTALLDIRS=vendor DESTDIR="${pkgdir}"
  39   # Delete unuseful files
  40   find "${pkgdir}" -name '.packlist' -delete
  41 }