perl-image-sane/trunk/PKGBUILD

   1 # Maintainer: Muflone http://www.muflone.com/contacts/english/
   2 # Contributor: John D Jones III AKA jnbek <jnbek1972 -_AT_- g m a i l -_Dot_- com>
   3 # Contributor: Stefan Husmann <stefan-husmann@t-online.de>
   4
   5 pkgname=perl-image-sane
   6 _perl_namespace=Image
   7 _perl_module=Sane
   8 pkgver=5
   9 pkgrel=4
  10 pkgdesc="Perl extension for the SANE (Scanner Access Now Easy) Project"
  11 arch=('x86_64')
  12 url="https://metacpan.org/release/${_perl_namespace}-${_perl_module}"
  13 license=('PerlArtistic' 'GPL')
  14 makedepends=('imagemagick')
  15 depends=('perl' 'sane' 'perl-extutils-depends' 'perl-extutils-pkgconfig' 'perl-readonly' 'perl-test-requires' 'perl-exception-class' 'perl-try-tiny')
  16 provides=('perl-sane')
  17 replaces=('perl-sane')
  18 conflicts=('perl-sane')
  19 source=("https://www.cpan.org/modules/by-module/${_perl_namespace}/${_perl_namespace}-${_perl_module}-${pkgver}.tar.gz")
  20 sha256sums=('229aa0e9f049efa760f3c2f6e61d9d539af43d8f764b50a6e03064b4729a35ff')
  21 options=('!emptydirs')
  22
  23 build() {
  24   cd "${_perl_namespace}-${_perl_module}-${pkgver}"
  25   unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  26   export PERL_MM_USE_DEFAULT=1 PERL_AUTOINSTALL=--skipdeps
  27   perl Makefile.PL
  28   make
  29 }
  30
  31 check() {
  32   cd "${_perl_namespace}-${_perl_module}-${pkgver}"
  33   unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  34   export PERL_MM_USE_DEFAULT=1
  35   make test
  36 }
  37
  38 package() {
  39   cd "${_perl_namespace}-${_perl_module}-${pkgver}"
  40   unset PERL5LIB PERL_MM_OPT PERL_MB_OPT PERL_LOCAL_LIB_ROOT
  41   make pure_install INSTALLDIRS=vendor DESTDIR="${pkgdir}"
  42   # Delete unuseful files
  43   find "${pkgdir}" -name '.packlist' -delete
  44 }