perl-unicode-stringprep/repos/community-any/PKGBUILD

   1 # Maintainer: Sergej Pupykin <pupykin.s+arch@gmail.com>
   2
   3 pkgname=perl-unicode-stringprep
   4 pkgver=1.105
   5 pkgrel=8
   6 pkgdesc="Preparation of Internationalized Strings (RFC 3454)"
   7 arch=('any')
   8 url="https://search.cpan.org/dist/Unicode-Stringprep/"
   9 license=('GPL' 'PerlArtistic')
  10 depends=('perl')
  11 makedepends=('perl-module-build>=0.42')
  12 checkdepends=('perl-test-nowarnings')
  13 provides=("perl-unicode-stringprep-bidi=$pkgver" "perl-unicode-stringprep-mapping=$pkgver"
  14           "perl-unicode-stringprep-prohibited=$pkgver" "perl-unicode-stringprep-unassigned=$pkgver")
  15 options=(!emptydirs)
  16 source=("https://search.cpan.org/CPAN/authors/id/C/CF/CFAERBER/Unicode-Stringprep-$pkgver.tar.gz")
  17 md5sums=('bf9ffbc387cc12d67a3875be1cd8e105')
  18 _ddir="Unicode-Stringprep-$pkgver"
  19
  20 build()
  21 (
  22   cd "$srcdir/$_ddir"
  23   export PERL_MM_USE_DEFAULT=1 MODULEBUILDRC=/dev/null
  24   unset PERL5LIB PERL_MB_OPT
  25   /usr/bin/perl Build.PL
  26   ./Build
  27 )
  28
  29 check()
  30 (
  31   cd "$srcdir/$_ddir"
  32   export PERL_MM_USE_DEFAULT=1 MODULEBUILDRC=/dev/null
  33   unset PERL5LIB PERL_MB_OPT
  34   ./Build test
  35 )
  36
  37 package()
  38 (
  39   cd "$srcdir/$_ddir"
  40   export PERL_MM_USE_DEFAULT=1 MODULEBUILDRC=/dev/null
  41   unset PERL5LIB PERL_MB_OPT
  42   ./Build install installdirs=vendor destdir="$pkgdir"
  43   find "$pkgdir" -name .packlist -o -name perllocal.pod -delete
  44 )