pipe-rename/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=pipe-rename
   4 pkgver=1.6.2
   5 pkgrel=1
   6 pkgdesc='Rename your files using your favorite text editor'
   7 arch=('x86_64')
   8 url='https://github.com/marcusbuffett/pipe-rename'
   9 license=('MIT')
  10 depends=('glibc' 'gcc-libs')
  11 makedepends=('git' 'rust')
  12 options=('!lto')
  13 _commit='2db7c4eabb5f2560c294c72b37bdbf6354e9cc66'
  14 source=(
  15   "$pkgname::git+$url#commit=$_commit"
  16   'LICENSE'
  17 )
  18 sha512sums=('SKIP'
  19             '3a3dbfd7a5a8d02a3a96bb1652bd25cae21d1080b941ecd3bee3f46e98b4a2f30b4a7ecdeb1e55ec2bf8bfefbeb9500287acb964ccb7149a405ee28eebd05889')
  20 b2sums=('SKIP'
  21         'abec091be86ec71b15a70251d769d4177639881c28d71fb9127d86cf711514e0fe40e80edd645e97df532980baf13380433fd2b497e03b4021d49e87434a4965')
  22
  23 pkgver() {
  24   cd "$pkgname"
  25
  26   git describe --tags | sed 's/^v//'
  27 }
  28
  29 prepare() {
  30   cd "$pkgname"
  31
  32   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  33 }
  34
  35 build() {
  36   cd "$pkgname"
  37
  38   cargo build --frozen --release
  39 }
  40
  41 package() {
  42   cd "$pkgname"
  43
  44   # binary
  45   install -vDm755 -t "$pkgdir/usr/bin" target/release/renamer
  46
  47   # documentation
  48   install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
  49
  50   # license
  51   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" "$srcdir/LICENSE"
  52 }