piping-server/trunk/PKGBUILD

   1 # Maintainer: Justin Kromlinger <hashworks@archlinux.org>
   2 pkgname=piping-server
   3 pkgver=0.16.0
   4 pkgrel=1
   5 pkgdesc='Infinitely transfer between every device over pure HTTP with pipes or browsers'
   6 arch=('x86_64')
   7 url="https://github.com/nwtgck/piping-server-rust"
   8 license=('MIT')
   9 depends=('gcc-libs')
  10 makedepends=('cargo')
  11 options=(!lto)
  12 source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz"
  13         "$pkgname.service")
  14 sha256sums=('3735eea652c178ec36118958414b7ce35a246fd64790e2fd04b5d5912f072d30'
  15             '9182467638a583b29bed0ae69ed00013b1721ce8753e5ba90a56cbaac07d768c')
  16
  17 build() {
  18   cd "piping-server-rust-$pkgver"
  19   cargo build --release --locked --target-dir=target
  20 }
  21
  22 check() {
  23   cd "piping-server-rust-$pkgver"
  24   cargo test --release --locked
  25 }
  26
  27 package() {
  28   install -Dm644 piping-server.service "$pkgdir/usr/lib/systemd/system/piping-server.service"
  29
  30   cd "piping-server-rust-$pkgver"
  31
  32   install -Dm755 "target/release/$pkgname" "$pkgdir/usr/bin/$pkgname"
  33
  34   install -Dm 644 "LICENSE" "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  35   install -Dm 644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
  36 }