powerdns-recursor/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Maintainer: Remi Gacogne <rgacogne[at]archlinux[dot]org>
   3 # Contributor: Alexander Rødseth <rodseth@gmail.com>
   4 # Contributor: Jan de Groot <jgc@archlinux.org>
   5 # Contributor: Jan Steffens <heftig@archlinux.org>
   6
   7 pkgname=powerdns-recursor
   8 pkgver=4.8.4
   9 pkgrel=1
  10 pkgdesc='Resolving DNS server'
  11 url='https://www.powerdns.com/'
  12 arch=('x86_64')
  13 license=('GPL2')
  14 depends=('gcc-libs' 'boost-libs' 'libcurl.so' 'libsodium' 'systemd-libs' 'luajit' 'openssl'
  15          'libboost_context.so' 'fstrm' 'net-snmp')
  16 makedepends=('boost' 'pandoc' 'ragel' 'systemd')
  17 provides=('pdns-recursor')
  18 conflicts=('pdns-recursor')
  19 backup=('etc/powerdns/recursor.conf')
  20 source=(https://downloads.powerdns.com/releases/pdns-recursor-${pkgver}.tar.bz2{,.asc}
  21         sysusers.conf)
  22 sha512sums=('1cfdf94bc10d01ebfae00780304f0d46b3388d824158195e1db2b04a08143cc8f36c4861a05ac8cbc05948349aafe1c9e822a27b15b470ef89a81e8bd584a5f2'
  23             'SKIP'
  24             '63b3f0664d38fbbcb6b1c914cee050a27eca0a15550962973743580dd5d3ace2e68272ca2d856d53cc74001fe9246d61207ebbc74524c096736777ed08c88e72')
  25 validpgpkeys=('FBAE0323821C7706A5CA151BDCF513FA7EED19F3'  # Peter van Dijk <peter.van.dijk@powerdns.com>
  26               '16E12866B7738C73976A57436FFC33439B0D04DF') # Winkels, Erik <erik.winkels@open-xchange.com>
  27
  28 prepare() {
  29   cd pdns-recursor-${pkgver}
  30   autoreconf -i
  31 }
  32
  33 build() {
  34   cd pdns-recursor-${pkgver}
  35   ./configure \
  36     --prefix=/usr \
  37     --sbindir=/usr/bin \
  38     --sysconfdir=/etc/powerdns \
  39     --disable-silent-rules \
  40     --enable-reproducible \
  41     --enable-systemd \
  42     --enable-dns-over-tls \
  43     --with-libsodium \
  44     --with-lua=luajit \
  45     --with-service-user=pdns-recursor \
  46     --with-service-group=pdns-recursor
  47   make
  48 }
  49
  50 package() {
  51   cd pdns-recursor-${pkgver}
  52   make DESTDIR="${pkgdir}" install
  53   mv "${pkgdir}/etc/powerdns/recursor.conf"{-dist,}
  54   install -Dm 644 "${srcdir}/sysusers.conf" "${pkgdir}/usr/lib/sysusers.d/powerdns-recursor.conf"
  55 }
  56
  57 # vim: ts=2 sw=2 et: