pragha/trunk/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2 # Contributor: Konstantin Gizdov <arch@kge.pw>
   3 # Contributor: Alad Wenter <alad@archlinux.org>
   4 # Contributor: Thorsten Töpper <atsutane-tu@freethoughts.de>
   5 # Contributor: J0k3r <moebius282 e4a t gmail D0_T com>
   6 # Contributor: Alois Nespor <alois.nespor@gmail.com>
   7 # Contributor: JerichoKru   <jerichokru(AT)hotmail.com>
   8
   9 pkgname=pragha
  10 pkgver=1.3.4
  11 pkgrel=5
  12 pkgdesc='Lightweight GTK music player and manager'
  13 arch=('x86_64')
  14 url='https://pragha-music-player.github.io/'
  15 license=('GPL3')
  16 depends=('cairo' 'gdk-pixbuf2' 'glib2' 'gstreamer' 'gst-plugins-base' 'gst-plugins-base-libs'
  17          'gst-plugins-good' 'gtk3' 'hicolor-icon-theme' 'libgudev' 'libpeas' 'pango' 'sqlite'
  18          'taglib' 'totem-pl-parser')
  19 optdepends=('glyr: Get Artist info, Lyrics and Album arts plugin'
  20             'grilo: DLNA Renderer plugin'
  21             'gst-libav: Extra media codecs'
  22             'gst-plugins-bad: Extra media codecs'
  23             'gst-plugins-ugly: Extra media codecs'
  24             'libcddb: Play cdrom plugin'
  25             'libcdio-paranoia: Play cdrom plugin'
  26             'libclastfm: Last.fm plugin'
  27             'libkeybinder3: Global Hotkeys plugin'
  28             'libmtp: MTP Devices plugin'
  29             'libnotify: Notification plugin'
  30             'libsoup: AcoustID and Get radios plugin')
  31 makedepends=('intltool' 'glyr' 'gobject-introspection' 'grilo' 'libcddb' 'libcdio-paranoia'
  32              'libclastfm' 'libkeybinder3'
  33              'libmtp' 'libnotify' 'libsoup')
  34 replaces=('dissonance')
  35 source=("https://github.com/pragha-music-player/$pkgname/releases/download/v$pkgver/$pkgname-$pkgver.tar.bz2")
  36 sha256sums=('e54e6acdc11e6f19c691c6e069fa9d54934c37b0f4b78cd5e835ce9512866ba6')
  37
  38 prepare() {
  39   cd $pkgname-$pkgver
  40   sed -i 's|(datadir)/appdata|(datadir)/metainfo|' data/Makefile.{am,in}
  41 }
  42
  43 build() {
  44   cd $pkgname-$pkgver
  45   ./configure --prefix=/usr
  46   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  47   make
  48 }
  49
  50 package() {
  51   cd $pkgname-$pkgver
  52   make DESTDIR="$pkgdir" install
  53 }