privoxy/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Lukas Fleischer <lfleischer@archlinux.org>
   2 # Contributor: Juergen Hoetzel <juergen@hoetzel.info>
   3 # Contributor: basilburn (basilburn), Paul Bredbury (brebs)
   4 # Contributor: lolilolicon
   5
   6 pkgname=privoxy
   7 pkgver=3.0.34
   8 pkgrel=1
   9 pkgdesc='A web proxy with advanced filtering capabilities.'
  10 arch=('x86_64')
  11 url='https://www.privoxy.org'
  12 license=('GPL2')
  13 depends=('pcre' 'zlib')
  14 backup=('etc/privoxy/'{config,trust,match-all.action,{default,user}.{action,filter}}
  15         'etc/logrotate.d/privoxy')
  16 source=("https://downloads.sourceforge.net/ijbswa/${pkgname}-${pkgver}-stable-src.tar.gz"
  17         'privoxy.logrotate.d'
  18         'privoxy.sysusers'
  19         'privoxy.service')
  20 sha256sums=('e6ccbca1656f4e616b4657f8514e33a70f6697e9d7294356577839322a3c5d2c'
  21             '769740ea3c15228f24b559192e7b3f45b95dcf9040e2b25f15bfdfae8af86ce3'
  22             '6681231552f431962dda2ac49187df833b2b57544eac97ca94d1f4207b27b04c'
  23             '30237681b6b117ce0d21efb3eeb896202744a32f9740fede1011b5dc84ff9f23')
  24
  25 build() {
  26   cd "${srcdir}/${pkgname}-${pkgver}-stable"
  27
  28   autoheader
  29   autoconf
  30   ./configure --prefix=/usr --sysconfdir=/etc/privoxy --enable-compression
  31
  32   make
  33   sed -i '
  34     s+^confdir \.+confdir /etc/privoxy+
  35     s+^logdir \.+logdir /var/log/privoxy+
  36     s+^#\?user-manual .*+user-manual /usr/share/doc/privoxy/user-manual/+' config
  37 }
  38
  39 package() {
  40   cd "${srcdir}/${pkgname}-${pkgver}-stable"
  41
  42   install -Dm644 "$srcdir/privoxy.service" "$pkgdir/usr/lib/systemd/system/privoxy.service"
  43   install -Dm644 "$srcdir/privoxy.sysusers" "$pkgdir/usr/lib/sysusers.d/privoxy.conf"
  44   install -Dm644 "$srcdir/privoxy.logrotate.d" "$pkgdir/etc/logrotate.d/privoxy"
  45
  46   install -Dm755 {,"$pkgdir"/usr/bin/}privoxy
  47   install -Dm644 {,"$pkgdir"/usr/share/man/man8/}privoxy.8
  48   install -d -o42 -g42 "$pkgdir"/var/log/privoxy
  49
  50   install -d "$pkgdir"/etc/privoxy/
  51   install -m644 config trust *.{action,filter} "$pkgdir"/etc/privoxy/ # -m0660 upstream
  52   find templates -type f -exec install -Dm644 '{}' "$pkgdir"/etc/privoxy/'{}' \;
  53
  54   (d="$pkgdir"/usr/share/doc/privoxy
  55   cd doc/webserver
  56   install -Dm644 {privoxy-,"$d"/}index.html
  57   install -m644 p_doc.css ../../{AUTHORS,README,ChangeLog} "$d"/
  58   install -Dm644 {,"$d"/user-manual/}p_doc.css
  59   find user-manual developer-manual faq man-page \( -name '*.html' -o -name '*.jpg' \) \
  60     -exec install -Dm644 '{}' "$d"/'{}' \;)
  61 }