procs/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Orhun Parmaksız <orhun@archlinux.org>
   2 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   3 # Contributor: Filipe Nascimento <flipee at tuta dot io>
   4 # Contributor: Attenuation <ouyangjun1999@gmail.com>
   5
   6 pkgname=procs
   7 pkgver=0.14.0
   8 pkgrel=1
   9 pkgdesc="A modern replacement for ps written in Rust"
  10 arch=('x86_64')
  11 url="https://github.com/dalance/procs"
  12 license=('MIT')
  13 depends=('gcc-libs')
  14 makedepends=('cargo')
  15 source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
  16 sha256sums=('fa5af0951dc8aa63c0590f8c5c1136594866057704cfb1cdfc22ac3cc49437c6')
  17
  18 prepare() {
  19     cd "$pkgname-$pkgver"
  20     cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  21 }
  22
  23 build() {
  24     cd "$pkgname-$pkgver"
  25     cargo build --release --frozen
  26
  27     "target/release/$pkgname" --gen-completion zsh
  28     "target/release/$pkgname" --gen-completion bash
  29     "target/release/$pkgname" --gen-completion fish
  30 }
  31
  32 check() {
  33     cd "$pkgname-$pkgver"
  34     cargo test --frozen
  35 }
  36
  37 package() {
  38     cd "$pkgname-$pkgver"
  39     install -Dm 755 "target/release/$pkgname" -t "$pkgdir/usr/bin"
  40     install -Dm 644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
  41     install -Dm 644 "_$pkgname" -t "$pkgdir/usr/share/zsh/site-functions"
  42     install -Dm 644 "$pkgname.bash" "$pkgdir/usr/share/bash-completion/completions/$pkgname"
  43     install -Dm 644 "$pkgname.fish" -t "$pkgdir/usr/share/fish/vendor_completions.d"
  44 }
  45
  46 # vim: ts=2 sw=2 et: