progpick/trunk/PKGBUILD

   1 # Maintainer: kpcyrd <kpcyrd[at]archlinux[dot]org>
   2
   3 pkgname=progpick
   4 pkgver=0.2.0
   5 pkgrel=1
   6 pkgdesc='Bruteforce with a stream of permutations of a specific pattern'
   7 url='https://github.com/kpcyrd/progpick'
   8 arch=('x86_64')
   9 license=('GPL3')
  10 makedepends=('cargo' 'scdoc')
  11 source=(https://github.com/kpcyrd/${pkgname}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz
  12         https://github.com/kpcyrd/${pkgname}/releases/download/v${pkgver}/${pkgname}-${pkgver}.tar.gz.asc)
  13 b2sums=('7b45f66a8ef297ce2f20e561bd8689cda0c38bfdfcb909c0fd2e0643dfac5933fca59b33327d7135d7eb255bd66f7e49bacfd30ed1d2a7aa1ab79aa37e95fb89'
  14         'SKIP')
  15 validpgpkeys=("64B13F7117D6E07D661BBCE0FE763A64F5E54FD6")
  16
  17 prepare() {
  18   cd "${pkgname}-${pkgver}"
  19   cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
  20 }
  21
  22 build() {
  23   cd ${pkgname}-${pkgver}
  24   cargo build --frozen --release
  25   make docs
  26 }
  27
  28 check() {
  29   cd ${pkgname}-${pkgver}
  30   cargo test --frozen --release
  31 }
  32
  33 package() {
  34   cd ${pkgname}-${pkgver}
  35   install -Dm 755 target/release/${pkgname} -t "${pkgdir}/usr/bin"
  36   install -Dm 644 contrib/${pkgname}.1 -t "${pkgdir}/usr/share/man/man1"
  37 }
  38
  39 # vim: ts=2 sw=2 et: