puppet-resource_api/repos/community-any/PKGBUILD

   1 # Maintainer: Christian Rebischke <chris.rebischke@archlinux.org>
   2 # Contributor: Tim Meusel <tim@bastelfreak.de>
   3
   4 _gemname='puppet-resource_api'
   5 pkgname="ruby-${_gemname}"
   6 pkgver=1.8.13
   7 pkgrel=1
   8 pkgdesc='This library provides a simple way to write new native resources for puppet.'
   9 arch=('any')
  10 url='https://github.com/puppetlabs/puppet-resource_api'
  11 license=('Apache')
  12 depends=('ruby' 'ruby-hocon')
  13 makedepends=('ruby-rdoc')
  14 checkdepends=('ruby-rake' 'ruby-rspec' 'ruby-bundler')
  15 source=("${url}/archive/${pkgver}/${_gemname}-${pkgver}.tar.gz")
  16 noextract=("$_gemname-$pkgver.gem")
  17 options=("!emptydirs")
  18 sha512sums=('cc675e6142cf474fb0eea31259f9c738c5ed428a7546c0630411a4aa0fc45597424cb7056882460eb00103057ad286e60a5a774037b11c7a3f6d8a2f1e148ea1')
  19
  20 build() {
  21   cd "${srcdir}/${_gemname}-${pkgver}"
  22   gem build "${_gemname}.gemspec"
  23 }
  24
  25 check() {
  26   cd "${srcdir}/${_gemname}-${pkgver}"
  27   # tests currently don't work because of outdated and partially dependencies
  28   #rake test
  29 }
  30
  31 package() {
  32   cd "${srcdir}/${_gemname}-${pkgver}"
  33   local _gemdir="$(gem env gemdir)"
  34   gem install --verbose --ignore-dependencies --no-user-install --install-dir "${pkgdir}/${_gemdir}" --bindir "${pkgdir}/usr/bin" "${_gemname}-${pkgver}.gem"
  35
  36   install -Dm 644 NOTICE LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
  37   install -Dm 644 CHANGELOG.md CONTRIBUTING.md HISTORY.md README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  38
  39   rm -r "${pkgdir}/${_gemdir}/cache"
  40 }
  41
  42 # vim: ts=2 sw=2 et: