py3status/trunk/PKGBUILD

   1 # Maintainer: Morten Linderud <foxboron@archlinux.org>
   2 # Maintainer: Jonas Witschel <diabonas@archlinux.org>
   3 # Contributor: Maxim Baz <$pkgname at maximbaz dot com>
   4 # Contributor: Alexis "Horgix" Chotard <alexis.horgix.chotard@gmail.com>
   5 # Contributor: carstene1ns <arch carsten-teibes de> - http://git.io/ctPKG
   6
   7 pkgname=py3status
   8 pkgver=3.50
   9 pkgrel=1
  10 pkgdesc="An extensible i3status replacement/wrapper written in python"
  11 url="https://www.ultrabug.fr/tag/py3status/"
  12 arch=('any')
  13 license=('BSD')
  14 depends=('python' 'python-setuptools')
  15 makedepends=('python-build' 'python-installer' 'python-wheel')
  16 checkdepends=('python-pytest')
  17 optdepends=('i3status: for i3status modules'
  18             'i3blocks: for i3blocks modules'
  19             'iw: for the wifi module'
  20             'python-mpris2: for the mpris module'
  21             'python-pyudev: for udev event monitoring'
  22             'python-pydbus: for modules that rely on D-Bus'
  23             'python-pytz: for the clock module'
  24             'python-tzlocal: for the clock module'
  25             'pacman-contrib: for the arch_updates module')
  26 source=("$pkgname-$pkgver.tar.gz::https://github.com/ultrabug/py3status/archive/refs/tags/$pkgver.tar.gz")
  27 sha256sums=('092574de6247574e21ebe516b8f62eba230420da276b4ee51726e12c52d05095')
  28
  29 build() {
  30     cd "$pkgname-$pkgver"
  31     python -m build --wheel --no-isolation
  32 }
  33
  34 check() {
  35     cd "$pkgname-$pkgver"
  36     pytest
  37 }
  38
  39 package() {
  40     cd "$pkgname-$pkgver"
  41     python -m installer --destdir="$pkgdir" dist/*.whl
  42     install -d "$pkgdir/usr/share/doc/$pkgname"{,/dev-guide,/user-guide}
  43     install -m644 docs/*.md README.md CHANGELOG "$pkgdir/usr/share/doc/$pkgname"
  44     install -m644 docs/dev-guide/* "$pkgdir/usr/share/doc/$pkgname/dev-guide"
  45     install -m644 docs/user-guide/* "$pkgdir/usr/share/doc/$pkgname/user-guide"
  46     install -Dm644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
  47 }