python-agate-dbf/trunk/PKGBUILD

   1 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   2 # Contributor: Gabriel Magno <gabrielmagno1@gmail.com>
   3 # Contributor: Michał Pałubicki <maln0ir@gmx.com>
   4
   5 _pyname=agate-dbf
   6 pkgname=python-$_pyname
   7 pkgver=0.2.2
   8 pkgrel=6
   9 pkgdesc='Adds read support for dbf files to agate'
  10 arch=(any)
  11 url="https://$_pyname.readthedocs.org"
  12 license=(MIT)
  13 _pydeps=(agate
  14          dbfread
  15          sphinx_rtd_theme)
  16 depends=(python
  17          "${_pydeps[@]/#/python-}")
  18 makedepends=(python-setuptools
  19              python-sphinx)
  20 checkdepends=(python-pytest)
  21 _archive="$_pyname-$pkgver"
  22 source=("$_archive.tar.gz::https://github.com/wireservice/$_pyname/archive/$pkgver.tar.gz")
  23 sha256sums=('5b60feb4bbb48dd4dcabef2b0248f2b8d4c3d42d60d50971c8067dbb5b01d5f6')
  24
  25 build() {
  26         cd "$_archive"
  27         python setup.py build
  28         make -C docs html
  29         _rtd_theme_path="$(python -c 'import sphinx_rtd_theme; print(sphinx_rtd_theme.get_html_theme_path())')"
  30         rm -rvf docs/_build/html/_static
  31         ln -svf "$_rtd_theme_path/sphinx_rtd_theme/static" docs/_build/html/_static
  32 }
  33
  34 check() {
  35         cd "$_archive"
  36         pytest tests
  37 }
  38
  39 package() {
  40         cd "$_archive"
  41         python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  42         install -dm0755 "$pkgdir/usr/share/doc/"
  43         cp -rv docs/_build/html "$pkgdir/usr/share/doc/$pkgname"
  44         install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" COPYING
  45 }