python-alembic/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Contributor: googol <googol@posteo.de>
   3 # Contributor: Oliver Mangold <o.mangold at gmail dot com>
   4
   5 pkgname=python-alembic
   6 pkgver=1.9.4
   7 pkgrel=2
   8 pkgdesc='Lightweight database migration tool for usage with SQLAlchemy'
   9 url='https://github.com/sqlalchemy/alembic'
  10 arch=('any')
  11 license=('MIT')
  12 depends=('python' 'python-mako' 'python-sqlalchemy' 'python-editor'
  13          'python-dateutil' 'python-importlib-metadata')
  14 makedepends=('python-setuptools' 'python-mako' 'python-sqlalchemy' 'python-editor' 'python-dateutil')
  15 checkdepends=('python-pytest')
  16 source=(https://pypi.org/packages/source/a/alembic/alembic-${pkgver}.tar.gz{,.asc})
  17 sha512sums=('76e6f86e789cecff78f8e86c34d22a70615158833bc24a26f38fe2d0d5ccd098920e0fe4cbebaadd2c9a4a2e63152720945645000d46a2b6b8b6696ce873f899'
  18             'SKIP')
  19 b2sums=('5b740803b6bf5b715e9572a91d87d5403d64e665647776d28511704fa17ed81825fe6f5cdab2cec77a0806abb02ef2a7acf5f9702ff87639b90e74d9e22a4b1a'
  20         'SKIP')
  21 validpgpkeys=('83AF7ACE251C13E6BB7DEFBD330239C1C4DAFEE1') # Michael Bayer <classic@zzzcomputing.com>
  22
  23 prepare() {
  24   cd alembic-${pkgver}
  25   # do not treat warnings as errors
  26   sed 's|-p no:warnings||g' -i setup.cfg
  27 }
  28
  29 build() {
  30   cd alembic-${pkgver}
  31   python setup.py build
  32 }
  33
  34 check() {
  35   cd alembic-${pkgver}
  36   py.test
  37 }
  38
  39 package() {
  40   cd alembic-${pkgver}
  41   python setup.py install --root="${pkgdir}" --prefix=/usr -O1 --skip-build
  42   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  43   install -Dm 644 README.rst CHANGES -t "${pkgdir}/usr/share/doc/${pkgname}"
  44 }
  45
  46 # vim: ts=2 sw=2 et: