python-astroid/trunk/PKGBUILD

   1 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   2 # Maintainer: Daniel M. Capella <polyzen@archlinux.org>
   3 # Contributor: Angel Velasquez <angvp@archlinux.org>
   4 # Contributor: Felix Yan <felixonmars@archlinux.org>
   5
   6 _pyname=astroid
   7 pkgname=python-$_pyname
   8 pkgver=2.15.5
   9 pkgrel=1
  10 pkgdesc='A common base representation of python source code'
  11 arch=(any)
  12 url="https://github.com/PyCQA/$_pyname"
  13 license=(LGPL)
  14 _pydeps=(lazy-object-proxy
  15          typing-extensions
  16          wrapt)
  17 depends=(python
  18          "${_pydeps[@]/#/python-}")
  19 makedepends=(python-{build,installer,wheel}
  20              python-setuptools)
  21 checkdepends=(python-numpy
  22               python-pip
  23               python-pytest
  24               python-regex
  25               python-typed-ast
  26               python-urllib3)
  27 replaces=(python-logilab-astng)
  28 conflicts=(python-logilab-astng)
  29 _archive="$_pyname-$pkgver"
  30 source=("$url/archive/v$pkgver/$_archive.tar.gz")
  31 sha256sums=('c819b8f9c97a8365d907d837f1655dca3a0052a494e0c91ec9ad5df48f7a4101')
  32
  33 prepare() {
  34         cd "$_archive"
  35         sed -i -e '/^requires =/s/~=[0-9.]\+//g' pyproject.toml
  36 }
  37
  38 build() {
  39         cd "$_archive"
  40         python -m build -wn
  41 }
  42
  43 check() {
  44         cd "$_archive"
  45         pytest
  46 }
  47
  48 package() {
  49         cd "$_archive"
  50         python -m installer -d "$pkgdir" dist/*.whl
  51 }