python-async-lru/trunk/PKGBUILD

   1 # Maintainer: Antonio Rojas <arojas@archlinux.org>
   2
   3 _pyname=async-lru
   4 pkgname=python-$_pyname
   5 pkgver=2.0.2
   6 pkgrel=1
   7 pkgdesc='Simple LRU cache for asyncio'
   8 arch=(any)
   9 url='https://github.com/aio-libs/async-lru'
  10 license=(MIT)
  11 depends=(python-typing_extensions)
  12 makedepends=(python-build python-installer python-setuptools python-wheel)
  13 checkdepends=(python-pytest-cov python-pytest-asyncio python-pytest-timeout)
  14 source=(https://pypi.python.org/packages/source/${_pyname:0:1}/$_pyname/$_pyname-$pkgver.tar.gz)
  15 sha256sums=('3b87ec4f2460c52cc7916a0138cc606b584c75d1ef7d661853c95d1d3acb869a')
  16
  17 build() {
  18   cd $_pyname-$pkgver
  19   python -m build --wheel --no-isolation
  20 }
  21
  22 check() {
  23   cd $_pyname-$pkgver
  24   python -m venv --system-site-packages test-env
  25   test-env/bin/python -m installer dist/*.whl
  26   test-env/bin/python -m pytest -v
  27 }
  28
  29 package() {
  30   cd $_pyname-$pkgver
  31   python -m installer --destdir="$pkgdir" dist/*.whl
  32   install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
  33 }