python-authres/trunk/PKGBUILD

   1 # Maintainer: Daniel M. Capella <polyzen@archlinux.org>
   2 # Contributor: Rich Li <rich at dranek com>
   3 # Contributor: Thomas Haider <t.haider@deprecate.de>
   4 # Contributor: Filip S. Adamsen <fsa [at] fsadev [dot] com>
   5 # Contributor: Samed Beyribey <ras0ir@eventualis.org>
   6
   7 pkgname=python-authres
   8 pkgver=1.2.0
   9 pkgrel=9
  10 pkgdesc='Python Authentication-Results headers generation and parsing'
  11 arch=('any')
  12 url=https://launchpad.net/authentication-results-python
  13 license=('Apache')
  14 depends=('python')
  15 makedepends=('python-build' 'python-installer' 'python-setuptools'
  16              'python-wheel')
  17 source=("https://files.pythonhosted.org/packages/source/a/authres/authres-$pkgver.tar.gz")
  18 sha256sums=('93d1b995ad7ce21e62db649f361048125dd6022563a0ae8a23909465f1fd25b7')
  19
  20 build() {
  21   cd authres-$pkgver
  22   python -m build --wheel --skip-dependency-check --no-isolation
  23 }
  24
  25 check() {
  26   cd authres-$pkgver
  27   python -m authres -v
  28 }
  29
  30 package() {
  31   cd authres-$pkgver
  32   python -m installer --destdir="$pkgdir" dist/*.whl
  33 }