python-basemap/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>
   2 # Contributor: Stéphane Gaudreault <stephane@archlinux.org>
   3 # Contributor: Matthias Ellmer <ellmer.matthias@gmail.com>
   4 # Contributor: Julien Morin <jmorin@cp.dias.ie>
   5
   6 pkgbase=python-basemap
   7 pkgname=('python-basemap' 'python-basemap-common')
   8 pkgver=1.2.2
   9 pkgrel=4
  10 arch=('x86_64')
  11 url="https://matplotlib.org/basemap/"
  12 license=('MIT')
  13 makedepends=('cython' 'python-setuptools' 'python-matplotlib' 'geos' 'shapelib'
  14              'python-numpy' 'python-pyproj')
  15 source=($pkgname-$pkgver.tar.gz::https://github.com/matplotlib/basemap/archive/v${pkgver}rel.tar.gz
  16         LICENSE)
  17 sha256sums=('7e6ee5d03b10168862cff82bfa819df8264c04f078eac4549a22dd2631696613'
  18             '0deac85afb0740df7626b6d8d7aa4b8814bbe9a412fb1a0e5962895d17e63add')
  19
  20 prepare() {
  21   pushd "${srcdir}"/basemap-${pkgver}rel
  22 # regenerate cythonized sources
  23   cythonize --force src/_geoslib.pyx
  24 # Remove the bundled libraries and common data
  25   rm -r geos-*
  26   sed -i "s/lib64/lib/g" setup.py
  27   popd
  28 }
  29
  30 build() {
  31   cd "${srcdir}"/basemap-${pkgver}rel
  32   python setup.py config
  33   python setup.py build
  34 }
  35
  36 package_python-basemap() {
  37   pkgdesc="Toolkit for plotting data on map projections"
  38   depends=('python-basemap-common' 'python-matplotlib' 'geos' 'shapelib' 'python-numpy' 'python-pyproj')
  39   optdepends=('python-owslib: needed for the BaseMap.wmsimage function'
  40               'python-pillow: needed for Basemap warpimage, bluemarble, shadedrelief and etop methods')
  41
  42   cd "${srcdir}"/basemap-${pkgver}rel
  43
  44   python setup.py install -O1 --skip-build --root="${pkgdir}" --prefix=/usr
  45   install -Dm644 "${srcdir}"/LICENSE "${pkgdir}"/usr/share/licenses/${pkgname}/LICENSE
  46
  47   _sitepackages=`python -c "import site; print(site.getsitepackages()[0])"`
  48   rm -fr "${pkgdir}${_sitepackages}"/mpl_toolkits/basemap/data
  49   ln -sf /usr/share/basemap/data "${pkgdir}${_sitepackages}"/mpl_toolkits/basemap/data
  50 }
  51
  52 package_python-basemap-common() {
  53   pkgdesc="Data files for python-basemap"
  54   license=('GPL2')
  55
  56   cd "${srcdir}"/basemap-${pkgver}rel
  57
  58   install -dm755 "${pkgdir}"/usr/share/basemap
  59   cp -a lib/mpl_toolkits/basemap/data/ "${pkgdir}"/usr/share/basemap/
  60 }