python-bintrees/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 _pyname=bintrees
   4 pkgname=python-bintrees
   5 pkgver=2.2.0
   6 pkgrel=2
   7 pkgdesc='Package provides Binary-, RedBlack- and AVL-Trees'
   8 url='https://github.com/mozman/bintrees'
   9 arch=('x86_64')
  10 license=('custom')
  11 depends=('python')
  12 makedepends=('python-build' 'python-installer' 'python-wheel' 'python-setuptools' 'cython')
  13 source=("${url}/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz")
  14 sha512sums=('640b9979ff9ef25fedbc59c9203363039e732b1ecbeda6475126c7c872207e9b790b7c6c8e67457c029f0d5397c28e6767c1c49061693135206eece98bb203bf')
  15 b2sums=('4a4dce2529a0eb3ac2c9d34e2170e58517f87d82590cf910903e25dbb0c97e2d8b67c4fe46ac3ab664d46769e222095d2baf26fcf04925796384d71681fe80f5')
  16
  17 build() {
  18   cd "${_pyname}-${pkgver}"
  19   python setup.py build_ext -i
  20   python -m build --wheel --no-isolation
  21 }
  22
  23 check() {
  24   cd "${_pyname}-${pkgver}"
  25   python -m unittest discover
  26 }
  27
  28 package() {
  29   cd "${_pyname}-${pkgver}"
  30   python -m installer --destdir="${pkgdir}" dist/*.whl
  31   install -Dm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
  32   install -Dm 644 LICENSE.txt -t "${pkgdir}/usr/share/licenses/${pkgname}"
  33 }
  34
  35 # vim: ts=2 sw=2 et: