python-click-repl/repos/community-any/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2
   3 _name=click-repl
   4 pkgname=python-click-repl
   5 pkgver=0.2.0
   6 pkgrel=4
   7 pkgdesc="Subcommand REPL for click apps"
   8 arch=('any')
   9 url="https://github.com/click-contrib/click-repl"
  10 license=('MIT')
  11 depends=('python-click' 'python-prompt_toolkit' 'python-six')
  12 makedepends=('python-setuptools')
  13 checkdepends=('python-pytest')
  14 # https://github.com/click-contrib/click-repl/issues/49
  15 # source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
  16 source=("${pkgname}-${pkgver}.tar.gz::https://github.com/click-contrib/${_name}/archive/refs/tags/${pkgver}.tar.gz")
  17 sha512sums=('888ef2d4082cbecbdab70d707296b20d3dcc0a13fe06ef103fbe04a3f29381fe0f3284c2eb38c6d3eb8b026063cba470a519524e98b9eadd06a5946c669ffc3b')
  18 b2sums=('b02c7d858971f655ba880c6f66ff0a5c1b3c1aeb83782807c04d862430841761caa8a7a72d2d110a9706272cf2cd818b6976db14315c885bea95e8ef991ef9df')
  19
  20 prepare() {
  21   mv -v "${_name}-$pkgver" "$pkgname-$pkgver"
  22 }
  23
  24 build() {
  25   cd "$pkgname-$pkgver"
  26   python setup.py build
  27 }
  28
  29 check() {
  30   cd "$pkgname-$pkgver"
  31   export PYTHONPATH="build:${PYTHONPATH}"
  32   pytest -v
  33 }
  34
  35 package() {
  36   cd "$pkgname-$pkgver"
  37   python setup.py install --skip-build \
  38     --optimize=1 \
  39     --root="${pkgdir}"
  40   install -vDm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}/"
  41   install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}/"
  42 }