python-consolekit/repos/community-any/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=python-consolekit
   4 pkgver=1.4.1
   5 pkgrel=2
   6 pkgdesc='Additional utilities for click'
   7 arch=('any')
   8 url='https://consolekit.readthedocs.io/'
   9 license=('MIT')
  10 depends=(
  11   'python'
  12   'python-click'
  13   'python-colorama'
  14   'python-deprecation-alias'
  15   'python-domdf-python-tools'
  16   'python-mistletoe'
  17   'python-typing-extensions'
  18 )
  19 makedepends=(
  20   'git'
  21   'python-build'
  22   'python-installer'
  23   'python-flit-core'
  24 )
  25 optdepends=(
  26   'python-psutil: better terminal support'
  27 )
  28 _commit='c39a554528649cec11bac083ad44f14b865307a7'
  29 source=("$pkgname::git+https://github.com/domdfcoding/consolekit#commit=$_commit")
  30 b2sums=('SKIP')
  31
  32 pkgver() {
  33   cd "$pkgname"
  34
  35   git describe --tags | sed 's/^v//'
  36 }
  37
  38 build() {
  39   cd "$pkgname"
  40
  41   python -m build --wheel --no-isolation
  42 }
  43
  44 package() {
  45   cd "$pkgname"
  46
  47   python -m installer --destdir="$pkgdir" dist/*.whl
  48
  49   # license
  50   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  51 }