python-cython-lint/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=python-cython-lint
   4 pkgver=0.15.0
   5 pkgrel=1
   6 pkgdesc='A tool to lint Cython files'
   7 arch=('any')
   8 url='https://github.com/MarcoGorelli/cython-lint'
   9 license=('MIT')
  10 depends=(
  11   'python'
  12   'cython'
  13   'python-tokenize-rt'
  14   'python-pycodestyle'
  15 )
  16 makedepends=(
  17   'git'
  18   'python-build'
  19   'python-installer'
  20   'python-wheel'
  21   'python-setuptools'
  22 )
  23 checkdepends=('python-pytest')
  24 _commit='ee720d6332a996d755b8919de55fc75d408be768'
  25 source=("$pkgname::git+$url#commit=$_commit")
  26 b2sums=('SKIP')
  27
  28 pkgver() {
  29   cd "$pkgname"
  30
  31   git describe --tags | sed 's/^v//'
  32 }
  33
  34 build() {
  35   cd "$pkgname"
  36
  37   python -m build --wheel --no-isolation
  38 }
  39
  40 check() {
  41   cd "$pkgname"
  42
  43   PYTHONPATH="$(pwd)" pytest -v
  44 }
  45
  46 package() {
  47   cd "$pkgname"
  48
  49   python -m installer --destdir="$pkgdir" dist/*.whl
  50
  51   # license
  52   install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
  53 }