python-engineio/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 pkgname=python-engineio
   4 pkgver=4.4.1
   5 pkgrel=1
   6 pkgdesc='Python implementation of the Engine.IO realtime server'
   7 url='https://github.com/miguelgrinberg/python-engineio'
   8 arch=('any')
   9 license=('MIT')
  10 depends=('python' 'python-websocket-client' 'python-websockets' 'python-requests')
  11 optdepends=('python-eventlet: eventlet driver'
  12             'python-aiohttp: aiohttp driver'
  13             'python-tornado: tornado driver'
  14             'python-gevent: gevent driver'
  15             'python-gevent-websocket: gevent driver')
  16 makedepends=('python-setuptools' 'python-sphinx' 'python-six' 'python-eventlet' 'python-aiohttp' 'python-tornado'
  17              'python-urllib3' 'python-websocket-client' 'python-gevent' 'python-gevent-websocket' 'python-websockets'
  18              'python-build' 'python-installer' 'python-wheel')
  19 checkdepends=('python-pytest' 'python-pytest-runner')
  20 options=('!makeflags')
  21 source=(https://github.com/miguelgrinberg/python-engineio/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
  22 sha512sums=('a903ae4f5a4679f6d46fda09901b637ef8dcf2896ece8781460d27aab7c8da606e16a89ac5dea94c156d8196a7e931626b2310b41ddc61d4241b5e004ad2ca64')
  23 b2sums=('4ae5dd9887f4d3a70d4983d2a0f0de29b1a54d30961bfc430b8850ff4af73fa1cd9abad6caeb8248a44def42b02e26ecb0632dd9b4d57e2a7f44b33762659304')
  24
  25 build() {
  26   cd ${pkgname}-${pkgver}
  27   python -m build --wheel --no-isolation
  28   make -C docs man text SPHINXBUILD=sphinx-build
  29 }
  30
  31 check() {
  32   cd ${pkgname}-${pkgver}
  33   PYTHONPATH=build/lib python setup.py test
  34 }
  35
  36 package() {
  37   cd ${pkgname}-${pkgver}
  38   python -m installer --destdir="$pkgdir" dist/*.whl
  39   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  40   install -Dm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
  41   install -Dm 644 docs/_build/text/*.txt -t "${pkgdir}/usr/share/doc/${pkgname}"
  42   install -Dm 644 docs/_build/man/python-engineio.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
  43 }
  44
  45 # vim: ts=2 sw=2 et: