python-flask-mail/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 _pkgname=flask-mail
   4 pkgname=python-flask-mail
   5 pkgver=0.9.1
   6 pkgrel=10
   7 pkgdesc='Flask extension providing simple email sending capabilities'
   8 url='https://pythonhosted.org/Flask-Mail/'
   9 arch=('any')
  10 license=('BSD')
  11 depends=('python' 'python-flask' 'python-blinker')
  12 makedepends=('python-sphinx' 'python-setuptools')
  13 checkdepends=('python-nose' 'python-blinker' 'python-speaklater')
  14 source=(${pkgname}-${pkgver}.tar.gz::https://github.com/mattupstate/flask-mail/archive/${pkgver}.tar.gz
  15         ${pkgname}-fix-headers-for-attachments.patch::https://github.com/mattupstate/flask-mail/commit/e195fca6de1077cabb711426e6378f51dc39d598.patch
  16         unittest-mock.patch)
  17 sha512sums=('1cf45ee734b35bf05862a4e88070a743a7d3cc877e4dcdc55f5e0a9642631752c4bf1e23065212157e71e42c5fdb010de8a68b4ab9f8444f9fa096d62a7aad3d'
  18             '7e85212c213307ede608f57e00f3a7109408216d999ed6823caad758231aaac5493dbab9a625d46f4a42278641f8d56aa3733fc9f87bb4b912b87a62b16e6814'
  19             '6829afa8b22b80918a0a633e86accdfb10fe37ea5087de369bf0ae89bed65e6907ee9c8e22ab18497cff4cba4d60a25892d2fa0c3c8b3ab33cf8fd325620ff3a')
  20
  21 prepare() {
  22   cd ${_pkgname}-${pkgver}
  23   patch -Np1 < ../unittest-mock.patch
  24   patch -Np1 < ../${pkgbase}-fix-headers-for-attachments.patch
  25 }
  26
  27 build() {
  28   cd ${_pkgname}-${pkgver}
  29   python setup.py build
  30   sphinx-build -b text docs docs/_build/text
  31   sphinx-build -b man docs docs/_build/man
  32 }
  33
  34 check() {
  35   cd ${_pkgname}-${pkgver}
  36   nosetests
  37 }
  38
  39 package() {
  40   cd ${_pkgname}-${pkgver}
  41   python setup.py install --root="${pkgdir}" --optimize=1 --skip-build
  42   install -Dm 644 README.rst CHANGES -t "${pkgdir}/usr/share/doc/${pkgname}"
  43   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  44   install -Dm 644 docs/_build/text/*.txt -t "${pkgdir}/usr/share/doc/${pkgname}"
  45   install -Dm 644 docs/_build/man/flask-mail.1 "${pkgdir}/usr/share/man/man1/${pkgname}.1"
  46 }
  47
  48 # vim: ts=2 sw=2 et: