python-fontpens/trunk/PKGBUILD

   1 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   2 # Contributor: Guillaume Horel <guillaume.horel@gmail.com>
   3
   4 # Upstream test suite has a circular dependency (it uses fontparts which in
   5 # turn depends on this library) and thus cannot be run by default without
   6 # blocking installation until first building without tests.
   7 BUILDENV+=(!check)
   8
   9 _pyname=fontPens
  10 pkgname=python-${_pyname,,}
  11 pkgver=0.2.4
  12 pkgrel=7
  13 pkgdesc='A collection of classes implementing the pen protocol for manipulating glyphs'
  14 arch=(any)
  15 url="https://github.com/robotools/$_pyname"
  16 license=(BSD)
  17 depends=(python-fonttools)
  18 makedepends=(python-{build,installer,wheel}
  19             python-setuptools)
  20 checkdepends=(python-fontparts
  21               python-pytest)
  22 _archive="$_pyname-$pkgver"
  23 source=("https://files.pythonhosted.org/packages/source/${_pyname::1}/$_pyname/$_archive.zip")
  24 sha256sums=('a6d9a14573b3450f3313d69523f9006028c21fc7aef5d35333b87aab7f2b41fd')
  25
  26 build() {
  27         cd "$_archive"
  28         python -m build -wn
  29 }
  30
  31 check() {
  32         cd "$_archive"
  33         PYTHONPATH=Lib pytest Lib
  34 }
  35
  36 package() {
  37         cd "$_archive"
  38         python -m installer -d "$pkgdir" dist/*.whl
  39         install -Dm0644 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE.txt
  40 }