python-fonttools/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Andrzej Giniewicz <gginiu@gmail.com>
   2 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   3 # Contributor: Firmicus <firmicus āt gmx dōt net>
   4 # Contributor: flying sheep <flying-sheep@web.de>
   5
   6 pkgname=python-fonttools
   7 _pyname=${pkgname#python-}
   8 pkgver=4.39.4
   9 pkgrel=1
  10 pkgdesc='A library to manipulate font files from Python'
  11 url="https://github.com/fonttools/$_pyname"
  12 license=('MIT')
  13 arch=('x86_64')
  14 depends=('python')
  15 makedepends=('cython'
  16              'python-'{build,installer}
  17              'python-setuptools'
  18              'python-wheel')
  19 checkdepends=('python-brotli'
  20               'python-fs'
  21               'python-pytest'
  22               'python-ufolib2')
  23 optdepends=('python-brotli: to compress/decompress WOFF 2.0 web fonts'
  24             'python-fs: to read/write UFO source files'
  25             'python-lxml: faster backend for XML files reading/writing'
  26             'python-lz4: for graphite type tables in ttLib/tables'
  27             'python-matplotlib: for visualizing DesignSpaceDocument and resulting VariationModel'
  28             'python-pyqt5: for drawing glyphs with Qt’s QPainterPath'
  29             'python-reportlab: to drawing glyphs as PNG images'
  30             'python-scipy: for finding wrong contour/component order between different masters'
  31             'python-sympy: for symbolic font statistics analysis'
  32             'python-uharfbuzz: to use the Harfbuzz Repacker for packing GSUB/GPOS tables'
  33             'python-unicodedata2: for displaying the Unicode character names when dumping the cmap table with ttx'
  34             'python-zopfli: faster backend fom WOFF 1.0 web fonts compression')
  35 source=("$url/archive/$pkgver/$_pyname-$pkgver.tar.gz")
  36 sha256sums=('9fab7f15ad7a0b5cd040331090b726c81d8b0d7b043bb348c7dc242d901b4ee5')
  37
  38 build() {
  39         cd "$_pyname-$pkgver"
  40         python -m build -wn
  41 }
  42
  43 check() {
  44         cd "$_pyname-$pkgver"
  45         PYTHONPATH=Lib pytest
  46 }
  47
  48 package() {
  49         cd "$_pyname-$pkgver"
  50         python -m installer -d "$pkgdir" dist/*.whl
  51         install -Dm0755 -t "$pkgdir/usr/share/licenses/$pkgname/" LICENSE
  52 }