python-git-url-parse/repos/community-any/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2
   3 _name=git-url-parse
   4 pkgname=python-git-url-parse
   5 pkgver=1.2.2
   6 pkgrel=5
   7 pkgdesc="A simple GIT URL parser"
   8 arch=('any')
   9 url="https://github.com/coala/git-url-parse"
  10 license=('MIT')
  11 depends=('python-pbr')
  12 makedepends=('python-setuptools')
  13 checkdepends=('python-pytest' 'python-pytest-cov' 'python-pytest-mock' 'yapf')
  14 source=("https://files.pythonhosted.org/packages/source/${_name::1}/${_name}/${_name}-${pkgver}.tar.gz")
  15 sha512sums=('d9a1633fd08b2d4bbd33ff886776906d2981f53178e295fb9907fdb261e863e2b70293d962962355b96ea156e17bb7e224497a4a708c8d9d0cc559d111fa188b')
  16
  17 prepare() {
  18   mv -v "${_name}-$pkgver" "$pkgname-$pkgver"
  19 }
  20
  21 build() {
  22   cd "$pkgname-$pkgver"
  23   python setup.py build
  24 }
  25
  26 check() {
  27   cd "$pkgname-$pkgver"
  28   export PYTHONPATH="build:${PYTHONPATH}"
  29   pytest -v
  30 }
  31
  32 package() {
  33   cd "$pkgname-$pkgver"
  34   python setup.py install --skip-build \
  35     --optimize=1 \
  36     --prefix=/usr \
  37     --root="${pkgdir}"
  38   install -vDm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  39   install -vDm 644 {AUTHORS,CHANGELOG,README}.rst \
  40     -t "${pkgdir}/usr/share/doc/${pkgname}"
  41 }