python-guessit/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=python-guessit
   4 pkgver=3.7.1
   5 pkgrel=2
   6 pkgdesc='A Python module that extracts as much information as possible from a video filename'
   7 arch=('any')
   8 url='https://github.com/guessit-io/guessit'
   9 license=('LGPL3')
  10 depends=(
  11   'python'
  12   'python-dateutil'
  13   'python-babelfish'
  14   'python-rebulk'
  15 )
  16 makedepends=(
  17   'git'
  18   'python-build'
  19   'python-installer'
  20   'python-wheel'
  21   'python-setuptools'
  22 )
  23 checkdepends=('python-pytest' 'python-pytest-mock' 'python-pyyaml')
  24 _commit='54acf7852a157db0f4842206c41db3cc6d36823b'
  25 source=("$pkgname::git+$url#commit=$_commit")
  26 b2sums=('SKIP')
  27
  28 pkgver() {
  29   cd "$pkgname"
  30
  31   git describe --tags | sed 's/^v//'
  32 }
  33
  34 build() {
  35   cd "$pkgname"
  36
  37   python -m build --wheel --no-isolation
  38 }
  39
  40 check() {
  41   cd "$pkgname"
  42
  43   PYTHONPATH="$PWD:$PYTHONPATH" pytest
  44 }
  45
  46 package() {
  47   cd "$pkgname"
  48
  49   python -m installer --destdir="$pkgdir" dist/*.whl
  50
  51   # delete tests from package
  52   local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
  53   rm -rf "$pkgdir$site_packages/guessit/test"
  54 }