python-jose/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2
   3 pkgname=python-jose
   4 pkgver=3.3.0
   5 pkgrel=4
   6 pkgdesc="A JOSE implementation in Python"
   7 arch=('any')
   8 license=('MIT')
   9 url="https://github.com/mpdavis/python-jose"
  10 depends=('python-rsa' 'python-six' 'python-ecdsa' 'python-future')
  11 optdepends=('python-cryptography: one option for better performance'
  12             'python-pycryptodome: one option for better performance')
  13 makedepends=('python-setuptools' 'python-rsa' 'python-six' 'python-ecdsa' 'python-future' 'python-pytest-runner')
  14 checkdepends=('python-cryptography' 'python-pycryptodome' 'python-pytest-cov')
  15 source=("https://github.com/mpdavis/python-jose/archive/$pkgver/$pkgname-$pkgver.tar.gz")
  16 sha512sums=('de7147cc6e12406d6e459c32829acae46395acba727c53e65bc05f4794ee3050eecd355e3ae2e87f4ebdbd871f53822eea08a10f25d7ca6088fc6128dc7d9637')
  17
  18 prepare() {
  19   cd python-jose-$pkgver
  20   sed -i 's/<0.15//' setup.py
  21 }
  22
  23 build() {
  24   cd python-jose-$pkgver
  25   python setup.py build
  26 }
  27
  28 check() {
  29   cd python-jose-$pkgver
  30   # https://github.com/mpdavis/python-jose/issues/176
  31   python setup.py pytest --addopts "--deselect tests/algorithms/test_EC.py::TestECAlgorithm::test_key_too_short"
  32 }
  33
  34 package() {
  35   cd python-jose-$pkgver
  36   python setup.py install --root="$pkgdir" --optimize=1
  37   install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  38 }