python-keyring/trunk/PKGBUILD

   1 # Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
   2 # Contributor: Johannes Dewender  arch at JonnyJD dot net
   3 # Contributor: Ivan Sichmann Freitas <ivansichfreitas@gmail.com>
   4 # Contributor: Brice Maron <brice@bmaron.net>
   5 # Contributor: Nuno Araujo <nuno.araujo at russo79.com>
   6 # Contributor: Steven Allen <steven {at} stebalien {dot} com>
   7
   8 pkgname=python-keyring
   9 _name=keyring
  10 pkgver=23.13.1
  11 pkgrel=1
  12 pkgdesc='Store and access your passwords safely'
  13 arch=('any')
  14 url='https://github.com/jaraco/keyring'
  15 license=('PSF' 'MIT')
  16 depends=('python-jaraco.classes' 'python-jeepney' 'python-secretstorage' 'python-importlib-metadata')
  17 makedepends=('python-build' 'python-installer' 'python-setuptools-scm' 'python-wheel')
  18 checkdepends=('python-pytest-flake8' 'python-pytest-runner' 'python-pytest-black' 'python-pytest-cov' 'python-pytest-mypy')
  19 optdepends=('python-keyrings-alt: Alternative backends'
  20             'python-dbus: kwallet backend')
  21 source=(https://files.pythonhosted.org/packages/source/${_name::1}/$_name/$_name-$pkgver.tar.gz)
  22 sha512sums=('7e56380e7311a31d8703b9e3beb74a8c8ce026f6cf9e1792780d349f3db61f50a1905c7d509a7013dd7cb47428dd3c28c3620815f01d3c4dbd7f648e056539d0')
  23 b2sums=('fb39490ba857f97b9b89856059664dfe21495ffe651bb48ad4e2284efe3f3c7551d34bfb4c39518c2b9b5e31e61b91693301271750f4ec837567d7652b11e9ef')
  24
  25 build() {
  26   cd $_name-$pkgver
  27
  28   python -m build
  29 }
  30
  31 check() {
  32   cd $_name-$pkgver
  33
  34   python -m pytest
  35 }
  36
  37 package() {
  38   cd $_name-$pkgver
  39
  40   python -m installer -d "$pkgdir" dist/*.whl
  41   install -Dm 644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  42
  43   local site_packages=$(python -c "import site; print(site.getsitepackages()[0])")
  44   rm -rf "$pkgdir"/$site_packages/keyring/tests
  45 }
  46
  47 # vim:set ts=2 sw=2 et: