python-nox/trunk/PKGBUILD

   1 # Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
   2
   3 _pkgname=nox
   4 pkgname=python-$_pkgname
   5 pkgver=2023.04.22
   6 pkgrel=1
   7 pkgdesc='Flexible test automation for Python'
   8 arch=('any')
   9 url='https://github.com/wntrblm/nox'
  10 license=('Apache')
  11 depends=('python' 'python-argcomplete' 'python-colorlog' 'python-py' 'python-virtualenv' 'python-packaging')
  12 optdepends=('python-jinja: tox_to_nox'
  13             'python-tox: tox_to_nox')
  14 makedepends=('python-build' 'python-installer' 'python-hatchling')
  15 checkdepends=('python-pytest-runner' 'python-jinja' 'python-tox')
  16 source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
  17 sha512sums=('7425588b0ae87d66211a4fec1d204122a2adb114ddca866d2e66e1caff930f593af1540e5c88806894400ea8aba92037d3f458a98df05d6ac70662705426ee6e')
  18
  19 build() {
  20   cd $_pkgname-$pkgver
  21
  22   python -m build -nw
  23 }
  24
  25 check() {
  26   cd $_pkgname-$pkgver
  27
  28   python -m venv --system-site-packages test-env
  29   test-env/bin/python -m installer dist/*.whl
  30 # tox 4 isn't supported https://github.com/wntrblm/nox/issues/673
  31   test-env/bin/python -m pytest -k 'not test_tox_to_nox'
  32 }
  33
  34 package() {
  35   cd $_pkgname-$pkgver
  36
  37   python -m installer -d "$pkgdir" dist/*.whl
  38
  39   install -Dm 644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  40 }
  41
  42 # vim:set ts=2 sw=2 et: