python-occ-core/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
   2
   3 _pkgname=pythonocc-core
   4 pkgname=python-${_pkgname#python}
   5 pkgver=7.6.2
   6 _commit=09d3747dbf6384f94d83ff2171e09259567823ff
   7 pkgrel=2
   8 pkgdesc='Python package for 3D CAD/BIM/PLM/CAM'
   9 arch=('x86_64')
  10 url='https://github.com/tpaviot/pythonocc-core'
  11 license=('LGPL3')
  12 depends=('python' 'opencascade' 'libxmu' 'libxi')
  13 # rapidjson appears to be unused but an opencascade
  14 # header that references it gets dragged in somehow
  15 makedepends=('cmake' 'swig' 'rapidjson' 'git' 'ninja')
  16 #source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
  17 source=("git+https://github.com/tpaviot/pythonocc-core#commit=$_commit")
  18 sha512sums=('SKIP')
  19
  20 pkgver() {
  21   cd $_pkgname-$pkgver
  22   git describe --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
  23 }
  24
  25 prepare() {
  26   mv $_pkgname $_pkgname-$pkgver
  27   cd $_pkgname-$pkgver
  28
  29   # Compatibility with opencascade 7.6.3
  30   git cherry-pick -n b4ddcf774549dbb3f89f4ca9f9c5db6c3c9ab48c
  31 }
  32
  33 build() {
  34   cd $_pkgname-$pkgver
  35
  36   cmake \
  37     -Bbuild \
  38     -GNinja \
  39     -DCMAKE_INSTALL_PREFIX=/usr \
  40     -DCMAKE_BUILD_TYPE=Release
  41
  42   ninja -C build
  43 }
  44
  45 package() {
  46   cd $_pkgname-$pkgver
  47
  48   DESTDIR="$pkgdir" ninja -C build install
  49 }