python-pbr/repos/community-any/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Contributor: Daniel Wallace <danielwallace at gtmanfred dot com>
   3 # Contributor: Limao Luo <luolimao+AUR@gmail.com>
   4
   5 pkgname=python-pbr
   6 pkgver=5.11.1
   7 pkgrel=5
   8 pkgdesc="Python Build Reasonableness"
   9 arch=('any')
  10 url='https://pypi.python.org/pypi/pbr'
  11 license=('Apache')
  12 depends=('python-importlib-metadata' 'python-setuptools')
  13 makedepends=('python-build' 'python-installer' 'python-wheel')
  14 checkdepends=('python-stestr' 'python-testscenarios' 'python-testresources' 'python-testrepository'
  15               'python-virtualenv' 'python-wheel' 'python-sphinx' 'git')
  16 source=("$pkgname-$pkgver.tar.gz::https://github.com/openstack-dev/pbr/archive/$pkgver.tar.gz")
  17 sha512sums=('59ff86c3cc43cc824dfa448ff87fa1fcdd2561c269c63115777811934fd616c893f5fe727d5624eb624d42a43de386cc311c5c029520a3131d5144db5a891da4')
  18
  19 export PBR_VERSION=$pkgver
  20
  21 build() {
  22   cd pbr-$pkgver
  23   python -m build --wheel --no-isolation
  24 }
  25
  26 check() {
  27   cd pbr-$pkgver
  28   # TODO: find out this failure
  29   stestr run --exclude-regex "pbr.tests.test_packaging.TestPackagingWheels.test_metadata_directory_has_pbr_json"
  30 }
  31
  32 package() {
  33   cd pbr-$pkgver
  34   python -m installer --destdir="$pkgdir" dist/*.whl
  35   install -Dm644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  36 }