python-pypandoc/repos/community-any/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2 # Maintainer: Caleb Maclennan <caleb@alerque.com>
   3
   4 pkgname=python-pypandoc
   5 pkgver=1.11
   6 pkgrel=2
   7 pkgdesc="Thin wrapper for pandoc"
   8 arch=('any')
   9 license=('MIT')
  10 url="https://github.com/bebraw/pypandoc"
  11 depends=('pandoc')
  12 makedepends=('python-build' 'python-installer' 'python-poetry-core' 'python-wheel')
  13 checkdepends=('texlive-core' 'texlive-latexextra')
  14 source=("https://github.com/bebraw/pypandoc/archive/v$pkgver/$pkgname-$pkgver.tar.gz")
  15 sha512sums=('1ca753ac2da9ad1a98c72aa639b6809e31d8c5da85a3a843f91675f95861e5056c183f67d73008c064b8fd2c82a4cd255f20b1c0073cc288a1e0e6a74caa9f94')
  16
  17 build() {
  18   cd pypandoc-$pkgver
  19   python -m build -wn
  20 }
  21
  22 check() {
  23   cd pypandoc-$pkgver
  24   # https://github.com/NicklasTegner/pypandoc/issues/278
  25   python tests.py || echo "Tests failed"
  26 }
  27
  28 package() {
  29   cd pypandoc-$pkgver
  30   python -m installer -d "$pkgdir" dist/*.whl
  31   install -D -m644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
  32 }