python-pytest-enabler/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2
   3 pkgname=python-pytest-enabler
   4 pkgver=2.1.1
   5 _commit=a4d55f8aa9c88b00327b9902676c9fb5a009f67f
   6 pkgrel=1
   7 pkgdesc='Enable installed pytest plugins'
   8 arch=('any')
   9 license=('MIT')
  10 url='https://github.com/jaraco/pytest-enabler'
  11 depends=('python-jaraco.context' 'python-jaraco.functools' 'python-pytest' 'python-toml')
  12 makedepends=('git' 'python-build' 'python-installer' 'python-setuptools-scm' 'python-wheel')
  13 checkdepends=('python-pytest-mypy' 'python-pytest-ruff')
  14 source=("git+https://github.com/jaraco/pytest-enabler.git#commit=$_commit"
  15         "https://files.pythonhosted.org/packages/source/t/types-toml/types-toml-0.10.1.tar.gz")
  16 sha512sums=('SKIP'
  17             '001757f956dd3af0688a6544b90ba415b26ab3128e0fbb238f4dfaf0bab6b5795d5598bcc9422d854ea235acbc9e78b245c17f9ebc9ad9251ae3c0722b382812')
  18
  19 prepare() {
  20   cd pytest-enabler
  21   # mypy needs all type stubs :/
  22   ln -s ../types-toml-0.10.1/toml-stubs .
  23 }
  24
  25 build() {
  26   cd pytest-enabler
  27   python -m build --wheel --no-isolation
  28 }
  29
  30 check() {
  31   cd pytest-enabler
  32   PYTHONPATH="$PWD" pytest
  33 }
  34
  35 package() {
  36   cd pytest-enabler
  37   python -m installer --destdir="$pkgdir" dist/*.whl
  38   install -Dm644 LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname/
  39 }
  40
  41 # vim:set ts=2 sw=2 et: