python-sphinx-issues/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2
   3 pkgname=python-sphinx-issues
   4 _pyname=${pkgname/python-/}
   5 pkgver=3.0.1
   6 pkgrel=2
   7 pkgdesc="Sphinx extension for linking to your project's issue tracker"
   8 url='https://github.com/sloria/sphinx-issues'
   9 arch=('any')
  10 license=('MIT')
  11 depends=('python' 'python-sphinx')
  12 makedepends=('python-setuptools')
  13 checkdepends=('python-pytest')
  14 source=(https://github.com/sloria/sphinx-issues/archive/${pkgver}/${_pyname}-${pkgver}.tar.gz)
  15 sha512sums=('dd64e1611eb58fc455bedb1658473fd71e4deab1371d8a42e6fa7fe3b128a991251add12e463b9a5826fd4eb5aa12e9a117dcf953feeb8df980a7951e43d8baa')
  16
  17 build() {
  18   cd ${_pyname}-${pkgver}
  19   python setup.py build
  20 }
  21
  22 check() {
  23   cd ${_pyname}-${pkgver}
  24   PYTHONPATH="$PWD" py.test
  25 }
  26
  27 package() {
  28   cd ${_pyname}-${pkgver}
  29   python setup.py install -O1 --root="${pkgdir}" --skip-build
  30   install -Dm 644 LICENSE -t "${pkgdir}/usr/share/licenses/${pkgname}"
  31   install -Dm 644 README.rst -t "${pkgdir}/usr/share/doc/${pkgname}"
  32 }
  33
  34 # vim: ts=2 sw=2 et: