python-webargs/repos/community-any/PKGBUILD

   1 # Maintainer: Filipe Laíns (FFY00) <lains@archlinux.org>
   2
   3 _pkgname=webargs
   4 pkgname=python-$_pkgname
   5 pkgver=8.2.0
   6 pkgrel=3
   7 pkgdesc='A friendly library for parsing HTTP request arguments, with built-in support for popular web frameworks'
   8 arch=('any')
   9 url='https://github.com/marshmallow-code/webargs'
  10 license=('MIT')
  11 depends=('python-marshmallow')
  12 makedepends=('python-setuptools' 'python-sphinx' 'python-sphinx-issues' 'python-sphinx-typlog-theme' 'python-sphinx-furo')
  13 checkdepends=('python-pytest-runner' 'python-webtest' 'python-pytest-aiohttp' 'python-webtest-aiohttp'
  14               'python-bottle' 'python-werkzeug' 'python-django' 'python-flask' 'python-tornado' 'python-pytest-asyncio')
  15 source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
  16 sha512sums=('9fc223b70333afe0985ff90648d6f59c94c97b87386df156038e3a6f7c0ac59526181d0a20107df6e060fe0fc9750de9144cbf2c07011cd54840000758eeedd5')
  17
  18 prepare() {
  19   cd $_pkgname-$pkgver
  20
  21   rm tests/test_{falcon,pyramid}parser.py
  22 }
  23
  24 build() {
  25   cd $_pkgname-$pkgver
  26
  27   python setup.py build
  28
  29   cd docs
  30
  31   make html man
  32   ls _build/man
  33   gzip _build/man/webargs.1
  34 }
  35
  36 check() {
  37   cd $_pkgname-$pkgver
  38
  39   python setup.py pytest
  40 }
  41
  42 package() {
  43   cd $_pkgname-$pkgver
  44
  45   python setup.py install --root="$pkgdir" --optimize=1 --skip-build
  46
  47   install -dm 755 "$pkgdir"/usr/share/doc/$pkgname
  48   cp -r -a --no-preserve=ownership docs/_build/html "$pkgdir"/usr/share/doc/$pkgname
  49
  50   install -dm 755 "$pkgdir"/usr/share/man/man1
  51   install -Dm 644 docs/_build/man/webargs.1.gz "$pkgdir"/usr/share/man/man1/webargs.1.gz
  52
  53   install -Dm 644 LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
  54 }
  55
  56 # vim:set ts=2 sw=2 et: