python-zita-jacktools/trunk/PKGBUILD

   1 # Maintainer: David Runge <dvzrv@archlinux.org>
   2
   3 _name=zita-jacktools
   4 pkgname=python-zita-jacktools
   5 pkgver=1.6.1
   6 pkgrel=2
   7 pkgdesc="Audio tools running as a Jack client"
   8 arch=(x86_64)
   9 url="https://kokkinizita.linuxaudio.org/linuxaudio"
  10 license=(GPL3)
  11 depends=(
  12   gcc-libs
  13   glibc
  14   python
  15   python-zita-audiotools
  16 )
  17 makedepends=(
  18   fftw
  19   jack
  20   libsndfile
  21   python-build
  22   python-installer
  23   python-setuptools
  24   python-wheel
  25   zita-convolver
  26   zita-jclient
  27   zita-resampler
  28 )
  29 optdepends=(
  30   'python-numpy: for examples'
  31   'python-pyqt5: for examples'
  32   'python-pyqt6: for examples'
  33 )
  34 source=(https://kokkinizita.linuxaudio.org/linuxaudio/downloads/$_name-$pkgver.tar.bz2)
  35 sha512sums=('c3969f81f1d7ca93bfe72ba4ab036fe133db4574aeb47121344c6c729fbf1c433dc89a5cbfb0278a0e92b0b944df9ebea590d70ba7a5f87b0143aca6cefab5c6')
  36 b2sums=('add63f0bbc130b9630e1139920fd8430e94aa5bc8f3410cd20e55a415b05e75fe0bbe3cab458f0b980bc914e8db8064cf82aeb86b894c32b25bedaa119f25469')
  37
  38 build() {
  39   cd $_name-$pkgver
  40   python -m build --wheel --no-isolation
  41 }
  42
  43 package() {
  44   depends+=(
  45     fftw libfftw3f.so
  46     jack libjack.so
  47     libsndfile libsndfile.so
  48     zita-convolver libzita-convolver.so
  49     zita-jclient libzita-jclient.so
  50     zita-resampler libzita-resampler.so
  51   )
  52
  53   cd $_name-$pkgver
  54   python -m installer --destdir="$pkgdir" dist/*.whl
  55
  56   # examples
  57   find examples -type f \( -iname "*.py" -or -iname "*README" -or -iname "*presets" \) -exec install -vDm 644 {} "$pkgdir/usr/share/doc/$pkgname/"{} \;
  58 }