python2-cherrypy/trunk/PKGBUILD

   1 # Maintainer:  Thore Bödecker <foxxx0@archlinux.org>
   2 # Contributor: Laurent Soest <laurent.soest@gmail.com>
   3 # Contributor: Angel Velasquez <angvp@archlinux.org>
   4 # Contributor: Kaiting Chen <kaitocracy@gmail.com>
   5 # Contributor: Douglas Soares de Andrade <dsa@aur.archlinux.org>
   6 # Contributor: Armando M. Baratti <amblistas@ajato.com.br>
   7 # Contributor: Florian Richter <Florian_Richter@gmx.de>
   8
   9 pkgname='python2-cherrypy'
  10 _pkgname="${pkgname#python2-}"
  11 pkgver=17.4.2
  12 pkgrel=1
  13 pkgdesc='A pythonic, object-oriented web development framework'
  14 arch=('any')
  15 url='https://cherrypy.org'
  16 license=('BSD')
  17 depends=('python2' 'python2-six' 'python2-cheroot' 'python2-more-itertools'
  18   'python2-portend' 'python2-jaraco' 'python2-contextlib2' 'python2-zc.lockfile')
  19 makedepends=('python2-setuptools' 'python2-setuptools-scm' 'python2-six'
  20   'python2-cheroot' 'python2-portend' 'python2-more-itertools'
  21   'python2-contextlib2' 'python2-zc.lockfile')
  22 checkdepends=('python2-tox')
  23 source=("${pkgname}-${pkgver}.tar.gz::https://github.com/${_pkgname}/${_pkgname}/archive/v$pkgver.tar.gz")
  24 sha512sums=('193b5b69b41d1651216795cc81556c90541cd54e125ae8a64ec00e1ad839a061a8af0330722ff6752f7c6a6505670cb36c082448854f1a380b5faafe135103f0')
  25
  26 prepare() {
  27   # fix python interpreter for python2 stuff
  28   find "${srcdir}/${_pkgname}-${pkgver}" -type f -name '*.py' \
  29     -exec sed -i 's|^#!/usr/bin/python$|#!/usr/bin/env python2|1' {} +
  30 }
  31
  32 build() {
  33   # setuptools wont find version from git tag
  34   export SETUPTOOLS_SCM_PRETEND_VERSION="${pkgver}"
  35   cd "${srcdir}/${_pkgname}-${pkgver}"
  36   python2 ./setup.py build
  37 }
  38
  39 check() {
  40   cd "${srcdir}/${_pkgname}-${pkgver}"
  41   tox2
  42 }
  43
  44 package() {
  45   cd "${srcdir}/${_pkgname}-${pkgver}"
  46
  47   python2 ./setup.py install --root="${pkgdir}" --optimize=1
  48   mv "${pkgdir}/usr/bin/cherryd" "${pkgdir}/usr/bin/cherryd2"
  49
  50   install -Dm644 LICENSE.md \
  51     "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE.md"
  52 }