radvd/trunk/PKGBUILD

   1 # Maintainer: Sébastien Luttringer
   2 # Maintainer: Thore Bödecker <foxxx0@archlinux.org>
   3 # Contributor: Kaiting Chen <kaitocracy@gmail.com>
   4 # Contributor: Mark Smith <markzzzsmith@yahoo.com.au>
   5
   6 pkgname=radvd
   7 pkgver=2.19
   8 pkgrel=1
   9 pkgdesc='IPv6 Router Advertisement Daemon'
  10 url='http://www.litech.org/radvd/'
  11 license=('custom')
  12 depends=('glibc')
  13 makedepends=('check')
  14 arch=('x86_64')
  15 backup=('etc/radvd.conf')
  16 # for unknown reasons upstream has stopped signing the tarballs since version 2.19
  17 validpgpkeys=(
  18   '10E2511038172B516DCA5BD36FE19F21451C9A2B' # Reuben Hawkins
  19   '7D0B3CEBE9B85B1F825BCECFEE05E6F6A48F6136' # Robin Hugh Johnson
  20 )
  21 source=("http://www.litech.org/radvd/dist/${pkgname}-${pkgver}.tar.xz"{,.asc}
  22         "${pkgname}.service")
  23 sha512sums=('a1eb40af90fc83ebab2517c16a0f7e85c11338ab276bec400b7c33177748d1e36bc5abd7e373b6742f12f7c690dd7ae6b951bc832c7de9bbb56f7e9bc844ed22'
  24             'SKIP'
  25             'f8abe3e0233c33313e768c45b2873bfc70b6461337c57ae6e07196d3e9d23338fdec56b1c92d3fa1a2a691f83fd850588095352570ce3d2c0cc32ac07862f426')
  26
  27 prepare() {
  28   cd "${srcdir}/${pkgname}-${pkgver}"
  29   :
  30 }
  31
  32 build() {
  33   cd "${srcdir}/${pkgname}-${pkgver}"
  34   ./configure \
  35     --prefix=/usr \
  36     --sbindir=/usr/bin \
  37     --sysconfdir=/etc \
  38     --with-pidfile=/run/radvd.pid \
  39     --with-check \
  40     --mandir=/usr/share/man
  41   make
  42 }
  43
  44 check() {
  45   cd "${srcdir}/${pkgname}-${pkgver}"
  46   make check
  47 }
  48
  49 package() {
  50   cd "${srcdir}/${pkgname}-${pkgver}"
  51   make DESTDIR="${pkgdir}" install
  52   # default config
  53   install -D -m 644 radvd.conf.example "${pkgdir}/etc/radvd.conf"
  54   # license
  55   install -D -m 644 COPYRIGHT "${pkgdir}/usr/share/licenses/${pkgname}/COPYRIGHT"
  56   # systemd
  57   install -D -m 644 "${srcdir}/${pkgname}.service" \
  58     "${pkgdir}/usr/lib/systemd/system/${pkgname}.service"
  59 }
  60
  61 # vim:set ts=2 sw=2 et: