rapid-photo-downloader/trunk/PKGBUILD

   1 # Maintainer: Jaroslav Lichtblau <svetlemodry@archlinux.org>
   2 # Contributor: Marc Moody <marc.r.moody at gmail dot com>
   3 # Contributor: Dinh Bowman <dinh at vagueindustries dot com>
   4
   5 pkgname=rapid-photo-downloader
   6 pkgver=0.9.34
   7 pkgrel=2
   8 pkgdesc="Photo and video downloader"
   9 arch=('any')
  10 url="https://www.damonlynch.net/rapid/"
  11 license=('GPL3')
  12 depends=('desktop-file-utils' 'gstreamer' 'hicolor-icon-theme' 'libgexiv2' 'libnotify' 'python-arrow'
  13          'perl-image-exiftool' 'python-colour' 'python-dateutil' 'python-easygui' 'python-gobject'
  14          'python-gphoto2' 'python-psutil' 'python-pymediainfo' 'python-pyqt5' 'python-pyzmq'
  15          'python-requests' 'python-setuptools' 'python-sortedcontainers' 'python-babel'
  16          'python-tornado' 'python-pyxdg' 'qt5-imageformats' 'udisks2' 'python-tenacity' 'qt5-svg'
  17          'python-show-in-file-manager')
  18 makedepends=('intltool' 'ifuse')
  19 optdepends=('ifuse: for iOS devices')
  20 changelog=$pkgname.changelog
  21 source=(https://launchpad.net/rapid/pyqt/${pkgver}/+download/${pkgname}-${pkgver}.tar.gz{,.asc}
  22         https://github.com/damonlynch/rapid-photo-downloader/commit/c3b62f04.patch)
  23 sha256sums=('2455ac84a8a51ed91500edaad1afb50f7adff2a437f4105360ac16311efb279e'
  24             'SKIP'
  25             'b606c23e74ff443a5793b2692864b743a68edde5845acc3f3325c3cf2d95f345')
  26 validpgpkeys=('E26048A9F4A803B91CB1BD648005B1F36970BE28') # Damon Lynch <damonlynch@gmail.com>
  27
  28 prepare() {
  29   cd $pkgname-$pkgver
  30   patch -p1 -i ../c3b62f04.patch # Fix build with setuptools 66
  31 }
  32
  33 build() {
  34   cd "${srcdir}"/$pkgname-$pkgver
  35
  36   python setup.py build
  37 }
  38
  39 package() {
  40   cd "${srcdir}"/$pkgname-$pkgver
  41
  42   python setup.py install --root="${pkgdir}" --optimize=1
  43 }