redo-sh/trunk/PKGBUILD

   1 # Maintainer: George Rawlinson <grawlinson@archlinux.org>
   2
   3 pkgname=redo-sh
   4 pkgver=4.0.4
   5 pkgrel=2
   6 pkgdesc="An implementation of the Redo build system in Bash"
   7 arch=('any')
   8 url="http://news.dieweltistgarnichtso.net/bin/redo-sh.html"
   9 license=('AGPL3')
  10 depends=('bash')
  11 makedepends=('git')
  12 optdepends=('graphviz: dependency graph support via redo-dot')
  13 provides=('redo')
  14 conflicts=('redo-python' 'redo-jdebp' 'redo-c')
  15 _commit='039767509a6b52707f9fc28e8dc16c2da294b92b'
  16 source=("$pkgname::git+http://news.dieweltistgarnichtso.net/bin.git#commit=$_commit")
  17 b2sums=('SKIP')
  18
  19 pkgver() {
  20   cd "$pkgname"
  21
  22   git describe --tags | sed 's/^redo-v//'
  23 }
  24
  25 prepare() {
  26   cd "$pkgname"
  27
  28   # description of each expression:
  29   # 1 - strip executable components in middle of file
  30   # 2 & 3 - remove shebang & subsequent 'cat' invocation
  31   # 4 - remove html comments
  32   # boom, we now have a valid HTML file
  33   sed -i \
  34     -e '/^EOF/,/^cat <<EOF/d' \
  35     -e '/#!\/bin\/sh/d' \
  36     -e '/cat <<EOF/d' \
  37     -e '/^<!--/,/^-->/d' \
  38     "redo-sh.do"
  39 }
  40
  41 package() {
  42   cd "$pkgname"
  43
  44   # scripts
  45   find . \
  46     -maxdepth 1 \
  47     -executable \
  48     -type f \
  49     -name "redo*" \
  50     -exec install -vDm755 -t "$pkgdir/usr/bin" "{}" +
  51
  52   # man pages
  53   find . \
  54     -maxdepth 1 \
  55     -type f \
  56     -name "redo*.1" \
  57     -exec install -vDm644 -t "$pkgdir/usr/share/man/man1" "{}" +
  58
  59   # documentation
  60   install -vDm644 "redo-sh.do" "$pkgdir/usr/share/doc/$pkgname/index.html"
  61 }
  62