retro-gtk/repos/community-x86_64/PKGBUILD

   1 # Maintainer: Balló György <ballogyor+arch at gmail dot com>
   2 # Contributor: Tom Richards <tom@tomrichards.net>
   3 # Contributor: TingPing <tingping@tingping.se>
   4 # Contributor: Omar Pakker <omar.pakker@oracle.com>
   5
   6 pkgname=retro-gtk
   7 pkgver=1.0.2
   8 pkgrel=1
   9 pkgdesc='Toolkit to write GTK+ 3 based Libretro frontends'
  10 arch=('x86_64')
  11 license=('GPL3')
  12 url='https://wiki.gnome.org/Apps/Games'
  13 depends=('libepoxy' 'glib2' 'gtk3' 'libpulse' 'libsamplerate')
  14 makedepends=('gobject-introspection' 'meson' 'vala' 'git' 'gtk-doc')
  15 provides=('libretro-gtk-1.so')
  16 _commit=422b70aa9465ea65ea70edcc9a093368cac22b2a  # tags/1.0.2^0
  17 source=("git+https://gitlab.gnome.org/GNOME/retro-gtk.git#commit=$_commit")
  18 sha256sums=('SKIP')
  19
  20 pkgver() {
  21   cd $pkgname
  22   git describe --tags | sed 's/-/+/g'
  23 }
  24
  25 build() {
  26   arch-meson $pkgname build \
  27     -D build-doc=true \
  28     -D install-doc=true
  29   meson compile -C build
  30 }
  31
  32 check() {
  33   # Tests try to run the installed /usr/lib/retro-runner
  34
  35   #dbus-run-session xvfb-run \
  36   #  -s '-screen 0 1920x1080x24 -nolisten local' \
  37   #  meson test -C build --print-errorlogs
  38   :
  39 }
  40
  41 package() {
  42   DESTDIR="$pkgdir" meson install -C build
  43 }