rime-terra-pinyin/trunk/PKGBUILD

   1 # Maintainer: Felix Yan <felixonmars@archlinux.org>
   2
   3 pkgname=rime-terra-pinyin
   4 pkgver=0.0.0.20230207
   5 _commit=9427853de91d645d9aca9ceace8fe9e9d8bc5b50
   6 pkgrel=1
   7 pkgdesc="Terra pinyin for rime"
   8 arch=('x86_64')
   9 url="https://github.com/rime/rime-terra-pinyin"
  10 license=('LGPL')
  11 # dependency for reverse lookup
  12 depends=('rime-stroke')
  13 makedepends=('git' 'librime' 'rime-prelude' 'rime-essay')
  14 source=("git+https://github.com/rime/rime-terra-pinyin.git#commit=$_commit")
  15 sha512sums=('SKIP')
  16
  17 prepare() {
  18   cd $pkgname
  19   # Link essentials
  20   for _f in $(pacman -Qql rime-prelude rime-essay | grep -v "/$"); do ln -sf $_f; done
  21 }
  22
  23 build(){
  24   cd $pkgname
  25   for _s in $(ls *.schema.yaml); do rime_deployer --compile $_s; done
  26 }
  27
  28 package() {
  29   cd $pkgname
  30   find . -type l -delete
  31   rm build/*.txt
  32   install -Dm644 *.yaml -t "$pkgdir"/usr/share/rime-data/
  33   install -Dm644 build/* -t "$pkgdir"/usr/share/rime-data/build/
  34 }