ruby-async/trunk/PKGBUILD

   1 # Maintainer: Levente Polyak <anthraxx[at]archlinux[dot]org>
   2 # Maintainer: Andreas 'Segaja' Schleifer <segaja at archlinux dot org>
   3
   4 _gemname=async
   5 pkgname=ruby-${_gemname}
   6 pkgver=1.30.3
   7 pkgrel=2
   8 pkgdesc='Composable asynchronous I/O'
   9 url='https://github.com/socketry/async'
  10 arch=('any')
  11 license=('MIT')
  12 depends=('ruby' 'ruby-console' 'ruby-nio4r' 'ruby-timers')
  13 makedepends=('ruby-rdoc')
  14 options=('!emptydirs')
  15 source=(https://github.com/socketry/async/archive/v${pkgver}/${pkgname}-${pkgver}.tar.gz)
  16 sha256sums=('f378e8d136c1b58f8df38956a5253b170f87ce815ae8c7d88b50ea964a8e8bb1')
  17 sha512sums=('337a51ca8fd0e6685528e2eca9b584344ba583f7254f2600110ee62da6e4ccabeb471e7d94f36ab6f8d0eb3eada9e23335a262a50c8d035f67708fce0a590e5e')
  18
  19 prepare() {
  20   cd ${_gemname}-${pkgver}
  21   sed 's|git ls-files|find|' -i ${_gemname}.gemspec
  22   sed 's|~>|>=|g' -i ${_gemname}.gemspec # don't give a fuck about rubys bla bla
  23 }
  24
  25 build() {
  26   cd ${_gemname}-${pkgver}
  27   gem build ${_gemname}.gemspec
  28 }
  29
  30 package() {
  31   cd ${_gemname}-${pkgver}
  32   local _gemdir="$(gem env gemdir)"
  33   gem install --ignore-dependencies --no-user-install -i "${pkgdir}/${_gemdir}" \
  34     -n "${pkgdir}/usr/bin" ${_gemname}-${pkgver}.gem
  35
  36   install -Dm 644 README.md -t "${pkgdir}/usr/share/doc/${pkgname}"
  37   install -Dm 644 README.md -t "${pkgdir}/usr/share/licenses/${pkgname}"
  38
  39   cd "${pkgdir}/${_gemdir}"
  40   rm -rf cache gems/${_gemname}-${pkgver}/{ext,lib/*/*.so} \
  41     extensions/*/*/${_gemname}-${pkgver}/{mkmf.log,gem_make.out}
  42 }
  43
  44 # vim: ts=2 sw=2 et: